# Maintainer: David Manouchehri <manouchehri@riseup.net>
# Contributor: Manuel Hüsers <manuel.huesers@uni-ol.de>
# Contributor: Romanos Skiadas <rom.skiad@gmail.com>
# Contributor: Melik Ludwig Manukyan <melik@archlinux.us>

_gitname=archey
pkgname="${_gitname}-git"
_gitbranch=master
_gitauthor=Manouchehri # djmelik
pkgver=r146.b74e40b
pkgrel=1
pkgdesc="A script that displays the arch logo and some basic information, written in Python."
url="https://github.com/${_gitauthor}/${_gitname}"
license=('GPL')
source=("git://github.com/${_gitauthor}/${_gitname}#branch=${_gitbranch}")
sha512sums=('SKIP')
arch=('any')
depends=('python')
makedepends=('git')
optdepends=('scrot: for taking screenshots of the output' 'lsb-release')
conflicts=("${_gitname}")
provides=("${_gitname}")

pkgver() {
  cd "${srcdir}/${_gitname}"
  (
    set -o pipefail
    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
      printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

package() {
  cd "${srcdir}/${_gitname}"
  install -D -m755 archey ${pkgdir}/usr/bin/archey # || return 1
  install -D -m644 COPYING ${pkgdir}/usr/share/licenses/archey/COPYING
}

# vim:set et sw=2 sts=2 tw=80: