# Maintainer: AtticFinder65536 <atticfinder -AT- rocklabs -DOT- xyz>
# Contributor: JianQing Liu <me at pegasis dot site>

# stable release

pkgname="discord-chat-exporter-cli"
_apkgname="DiscordChatExporter"
pkgver=2.42.8
pkgrel=1

pkgdesc="Exports Discord chat logs to a file"
url="https://github.com/Tyrrrz/$_apkgname"
license=(MIT)
arch=(any)

source=(
  "$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz"
  "$pkgname"
)
b2sums=(
  a310520df0785aae70ed95ffc97df3539d6a0d48e0f5abab3e606461ed375043b0248f86b6025a94c4f244edadbca34252a0fb340b17bb736c495167a33e385a
  7540fb95f81c1041c87778c590a9438ffb64bf417c3d4d3f1363da5a25898c98f9dcd1209b9237bd595374a33326b7f23043bd6156cc7e14f0bff230ee0f6de6
)

options=('!strip')

depends=('dotnet-runtime-8.0')
makedepends=('dotnet-sdk-8.0')

build() {
  cd "$_apkgname-$pkgver"
  dotnet publish "$_apkgname.Cli" --configuration "Release"
}

package() {
  install -Dm755 "$pkgname" "$pkgdir/usr/bin/$pkgname"

  cd "$_apkgname-$pkgver"
  install -Dm644 License.txt "$pkgdir/usr/share/licenses/$pkgname/License.txt"

  cd "$_apkgname.Cli/bin/Release/net8.0/publish"
  find . -type f -exec install -Dm644 "{}" "$pkgdir/usr/lib/$pkgname/{}" \;
}