# Maintainer: Marko Zivic <marko.b.zivic@gmail.com>
pkgname=endcord
pkgver=0.9.0
pkgrel=1
pkgdesc="Feature rich Discord TUI client."
arch=('any')
url="https://github.com/mzivic7/$pkgname"
license=('GPL')
depends=()
makedepends=('python>=3.11' 'python-pipenv' 'git')
optdepends=('xclip: clipboard support on X11'
            'wl-clipboard: clipboard support on Wayland'
            'aspell: spellchecking'
            'yt-dlp: youtube support'
            'mpv: youtube in native player')
source=("git+$url.git")
sha256sums=('SKIP')

pkgver() {
  cd "$pkgname"
  git describe --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
	cd "$pkgname"
	export PIPENV_VENV_IN_PROJECT=1
	pipenv install --dev
}

build() {
	cd "$pkgname"
	export PIPENV_VENV_IN_PROJECT=1
	pipenv run python build.py --build
}

package() {
	cd "$pkgname"
	install -Dm755 ./dist/$pkgname "$pkgdir/usr/bin/$pkgname"
	install -Dm644 ./README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
	install -Dm644 ./LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
}