# Maintainer: Xiaoxu Guo <ftiasch0@gmail.com>
# Maintainer: László Várady <laszlo.varady93@gmail.com>
# Maintainer: Carl Smedstad <carl.smedstad at protonmail dot com>
# Contributor: Daichi Shinozaki <dsdseg@gmail.com>

pkgname=folly
pkgver=2023.12.11.00
pkgrel=1
pkgdesc="An open-source C++ library developed and used at Facebook"
arch=(x86_64)
url="https://github.com/facebook/folly"
license=(Apache)
depends=(
  boost-libs
  bzip2
  double-conversion
  fmt
  gcc-libs
  gflags
  glibc
  google-glog
  libaio
  libevent
  libsodium
  libunwind
  liburing
  lz4
  openssl
  snappy
  xz
  zlib
  zstd
)
makedepends=(
  boost
  cmake
  gtest
)
provides=(
  libfolly.so
  libfolly_test_util.so
  libfollybenchmark.so
)
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('1ff0c0258f8322a818a6e0cd27c0fc965360dc04af308e59349e1c79966190a1')
options=(!lto)

_archive="$pkgname-$pkgver"

build() {
  cd "$_archive"

  # For the tests to compile, C++20 is needed. Building with C++20 produces a
  # number of compiler warnings, disable them to remove the noise.
  cmake -S . -B build \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -Wno-dev \
    -DBUILD_TESTS=ON \
    -DBUILD_SHARED_LIBS=ON \
    -DPACKAGE_VERSION="$pkgver" \
    -DCMAKE_CXX_STANDARD=20 \
    -DCMAKE_CXX_FLAGS="-Wno-unused-result -Wno-attributes -Wno-address -Wno-uninitialized -Wno-maybe-uninitialized"
  cmake --build build
}

check() {
  cd "$_archive"

  _skipped_tests=(
    # Skip failing tests - not sure why they fail.
    'HHWheelTimerTest'
    'async_helpers_test'
    'concurrent_hash_map_test'
    'executor_test'
    'fbstring_test'
    'future_dag_test'
    'future_test'
    'global_executor_test'
    'interrupt_test'
    'json_schema_test'
    'retrying_test'
    'serial_executor_test'
    'singleton_test_global'
    'timekeeper_test'
    'wait_test'
    'xlog_test'

    # Skip long-running tests.
    'concurrent_skip_list_test'
    'eliasfano_test'
    'f14_fwd_test'
    'small_locks_test'
  )
  _skipped_tests_pattern="${_skipped_tests[0]}"
  for test in "${_skipped_tests[@]:1}"; do
    _skipped_tests_pattern+="|$test"
  done
  ctest --test-dir build --output-on-failure -E "$_skipped_tests_pattern"
}

package() {
  cd "$_archive"

  DESTDIR="$pkgdir" cmake --install build
}