# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=fossil-fossil
pkgver=r17890.383f6d4
pkgrel=1
pkgdesc="A simple, high-reliability, distributed software configuration management system"
arch=('i686' 'x86_64')
url="https://fossil-scm.org/home/doc/trunk/www/index.wiki"
license=('BSD')
depends=('glibc' 'openssl' 'zlib')
makedepends=('fossil' 'tcl')
optdepends=('tcl')
provides=("fossil=$pkgver")
conflicts=('fossil')
backup=('etc/xinetd.d/fossil')
source=("fossil.fossil::fossil+https://fossil-scm.org/home"
        "fossil-xinetd::https://gitlab.archlinux.org/archlinux/packaging/packages/fossil/-/raw/main/fossil-xinetd"
        "fossil@.service::https://gitlab.archlinux.org/archlinux/packaging/packages/fossil/-/raw/main/fossil.service"
        "fossil.socket::https://gitlab.archlinux.org/archlinux/packaging/packages/fossil/-/raw/main/fossil.socket")
sha256sums=('SKIP'
            'SKIP'
            'SKIP'
            'SKIP')


pkgver() {
  cd "fossil"

  _info=$(fossil info)
  _hash=$(echo "$_info" | sed -n 's|checkout: *\([0-9a-z]*\).*|\1|p' | cut -c 1-7)
  _revision=$(echo "$_info" | sed -n 's|check-ins: *\(.*\)|\1|p')
  printf "r%s.%s" "$_revision" "$_hash"
}

build() {
  cd "fossil"

  ./configure \
    --prefix="/usr" \
    --with-tcl="/usr" \
    --with-tcl-private-stubs=1 \
    --json
  make
}

check() {
  cd "fossil"

  #make test
}

package() {
  cd "fossil"

  make DESTDIR="$pkgdir" install

  install -Dm644 "$srcdir/fossil-xinetd" "$pkgdir/etc/xinetd.d/fossil"
  install -Dm644 "$srcdir/"fossil{.socket,@.service} -t "$pkgdir/usr/lib/systemd/system"
  install -Dm644 "tools/fossil-autocomplete.bash" "$pkgdir/usr/share/bash-completion/completions/fossil"
  install -Dm644 "COPYRIGHT-BSD2.txt" -t "$pkgdir/usr/share/licenses/fossil"
}