# Maintainer: Leif Warner <abimelech@gmail.com>

# custom variables
_hkgname=gtk-traymanager

pkgname=haskell-gtk-traymanager
pkgver=1.0.1
pkgrel=1
license=(LGPL2.1)
pkgdesc="A wrapper around the eggtraymanager library for Linux system trays"
url="http://github.com/travitch/gtk-traymanager"
arch=('x86_64')
makedepends=("ghc")
depends=(
         "haskell-glib"
         "haskell-gtk")
source=("http://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")

sha256sums=("b19d79923b20fe12e451fff3c9a3ee0e79bd42e37fc4b0702cf4d0f2207f816d")

# PKGBUILD functions

build() {
    cd "${srcdir}/${_hkgname}-${pkgver}"
    
    runhaskell Setup configure -O --enable-executable-dynamic --disable-library-vanilla --enable-shared \
        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" \
        --libsubdir=\$compiler/site-local/\$pkgid --dynlibdir=/usr/lib
    runhaskell Setup build
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
}

package() {
    cd "${srcdir}/${_hkgname}-${pkgver}"
    
    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"

    runhaskell Setup copy --destdir="${pkgdir}"

    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
}