# Maintainer: Emil Velikov <emil.l.velikov@gmail.com>
# Maintainer: Yevhenii Kolesnikov <sigexp.acc@gmail.com>
# Contributor: Ben Widawsky <ben@bwidawsk.net>
# Contributor: Chad Versace <chad.versace@linux.intel.com>

_pkgbasename=waffle
pkgname=lib32-${_pkgbasename}
pkgver=1.6.3
pkgrel=2
pkgdesc='a library for choosing window system and OpenGL API at runtime (32 bits)'
arch=('x86_64')
url='http://www.waffle-gl.org'
license=('BSD')

depends=('lib32-libx11' 'lib32-libxcb' 'lib32-systemd' 'lib32-libgl' 'lib32-libgles' "${_pkgbasename}=${pkgver}")
optdepends=('lib32-libegl: for gbm, surfaceless, x11_egl or wayland support'
            'lib32-mesa: for gbm support'
            'lib32-wayland: for wayland support')
makedepends=('meson' 'xcb-proto' 'lib32-mesa' 'gcc-multilib' 'cmake')

source=(https://mesa.pages.freedesktop.org/waffle/files/release/waffle-${pkgver}/waffle-${pkgver}.tar.xz{,.asc})
sha256sums=('30e47bb78616e5deab1b94fd901c629a42b6ec3bf693c668217d4d5fd9b62219'
            'SKIP')
validpgpkeys=('8703B6700E7EE06D7A39B8D6EDAE37B02CEB490D')

build() {
	export CC='gcc -m32'
	export CXX='g++ -m32'
	export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'

	arch-meson "${_pkgbasename}-$pkgver" build \
		--buildtype release \
		--libdir=/usr/lib32 \
		-D gbm=enabled \
		-D glx=enabled \
		-D surfaceless_egl=enabled \
		-D x11_egl=enabled \
		-D wayland=enabled \
		-D build-manpages=false \
		-D build-htmldocs=false \
		-D build-examples=false

	meson configure build
	ninja -C build
}

package() {
	DESTDIR="$pkgdir" ninja -C build install

	mv "$pkgdir/usr/bin/wflinfo" "$pkgdir/usr/bin/wflinfo32"
	rm -rf "$pkgdir/usr/include"
	rm -rf "$pkgdir/usr/share"

	install -m755 -d "$pkgdir/usr/share/licenses"
	ln -s "${_pkgbasename}" "$pkgdir/usr/share/licenses/$pkgname"
}