# Maintainer: tristero <crf8472@mailbox.org>

pkgname=libarcsdec-git
pkgver=0.1.1alpha1+3.8aebeec
pkgrel=1
pkgdesc='Audio decoder and TOC parser adapters for libarcstk'
arch=('x86_64')
url="https://codeberg.org/tristero/${pkgname%-git}"
license=('MIT')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
depends=('gcc-libs' 'libarcstk'
	'libcue>=2.0.0' ## default metadata parsers
	'flac>=1.3.1' 'wavpack>=5.0.0' 'ffmpeg>=3.1') ## default audio decoders
makedepends=('git' 'cmake' 'flex' 'bison')
optdepends=('doxygen>=1.8.14: build documentation'
            'python-virtualenv: build HTML documentation with m.css')
source=("${pkgname%-git}::git+https://codeberg.org/tristero/${pkgname%-git}.git#branch=main")
md5sums=('SKIP')


pkgver()
{
	cd "${srcdir}/${pkgname%-git}"
	git describe --long HEAD | \
		sed 's/-\(alpha\|beta\|rc\)\.\([0-9]\+\)-/\1\2+/' | \
		sed 's/g\([a-z0-9]\+\)$/\1/' | \
		sed 's/-/./g'
}


## No prepare() function


build()
{
    printf "CMake Configure\n"

	cmake -DCMAKE_BUILD_TYPE=Release    \
		  -DCMAKE_INSTALL_PREFIX="/usr" \
		  "${srcdir}/${pkgname%-git}/"

    printf "CMake Build\n"

    cmake --build .
}


## No check() function


package()
{
	printf "Install library and files\n"

    make DESTDIR="${pkgdir}/" install

	printf "Install license\n"

	install -D -m644 "${srcdir}/${pkgname%-git}/LICENSE" \
		"${pkgdir}/usr/share/licenses/${pkgname%-git}/LICENSE"
}