# Maintainer: Dct Mei <dctxmei@yandex.com>
# Contributor: Eric S. Londres <elondres@stevens.edu>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: Cillian Berragan <cjberragan@gmail.com>
# Contributor: Felix Golatofski <contact@xdfr.de>

pkgname=nyxt
pkgver=2.2.2
pkgrel=1
pkgdesc="A keyboard-oriented, infinitely extensible web browser designed for power users"
arch=('x86_64')
url="https://github.com/atlas-engineer/nyxt"
license=('custom:BSD')
conflicts=('nyxt-browser')
provides=('nyxt-browser' 'next-browser')
source=("git+https://github.com/atlas-engineer/nyxt.git#tag=${pkgver}")
#source=("git+https://github.com/atlas-engineer/nyxt.git#tag=${pkgver//./-}"
#        "Makefile.2.pre.release.7.patch"
#        "renderer-gi-gtk.lisp.issue.1374.patch")
sha256sums=('SKIP')
# If someday Next works with other Lisps, replace 'sbcl' with 'common-lisp'.
makedepends=('cl-asdf' 'git' 'gobject-introspection-runtime' 'sbcl')
depends=('enchant' 'glib-networking' 'gobject-introspection-runtime' 'gsettings-desktop-schemas' 'libfixposix' 'webkit2gtk')
optdepends=('gstreamer: for HTML5 audio/video'
            'gst-plugins-base: for HTML5 audio/video'
            'gst-plugins-good: for HTML5 audio/video'
            'gst-plugins-bad: for HTML5 audio/video'
            'gst-plugins-ugly: for HTML5 audio/video')
# Binary will not run otherwise.
options=('!strip' '!makeflags')

#prepare() {
#    cd "${srcdir}"/"${pkgname}"/
#    patch -p1 -i ../Makefile.2.pre.release.7.patch
#    patch -p1 -i ../renderer-gi-gtk.lisp.issue.1374.patch
#}

build() {
    cd "${srcdir}"/"${pkgname}"/
    make all
}

package() {
    cd "${srcdir}"/"${pkgname}"/
    make install PREFIX=/usr DESTDIR="${pkgdir}"/
    install -Dm 644 licenses/ASSET-LICENSE -t "${pkgdir}"/usr/share/licenses/"${pkgname}"/
    install -Dm 644 licenses/SOURCE-LICENSE -t "${pkgdir}"/usr/share/licenses/"${pkgname}"/
}