# Maintainer: Matthias Blankertz <matthias at blankertz dot org>
# Contributor: Navkamal Rakra <navkamal90[at]gmail[dot]com>

pkgname=('ogdf-snapshot' 'ogdf-snapshot-docs')
pkgver=2018_03_28
pkgrel=3
pkgdesc="OGDF is a self-contained C++ class library for the automatic layout of diagrams. OGDF offers sophisticated algorithms and data structures to use within your own applications or scientific projects."
arch=('i686' 'x86_64')
url="https://ogdf.uos.de/"
license=('GPL')
makedepends=('cmake' 'doxygen' 'graphviz' 'bash')
conflicts=('ogdf' 'coin-or-clp' 'coin-or-osi' 'coin-or-coinutils')
provides=('ogdf')
source=("$pkgname-${pkgver//_/-}.zip::https://ogdf.uos.de/wp-content/uploads/2019/04/$pkgname-${pkgver//_/-}.zip")
sha256sums=("347c3fa8dcdbb094f9c43008cbc2934bc5a64a532af4d3fe360a5fa54488440f")

build() {
	cd "$srcdir/OGDF-snapshot"
	cmake -DCMAKE_CXX_FLAGS:STRING="${CXXFLAGS} ${CPPFLAGS} -Wno-class-memaccess -Wno-error=restrict -Wno-deprecated-copy -Wno-pessimizing-move -Wno-error=shadow" \
		-DCMAKE_EXE_LINKER_FLAGS:STRING="${LDFLAGS}" \
		-DCMAKE_POSITION_INDEPENDENT_CODE:BOOL=true \
	        -DCMAKE_INSTALL_PREFIX="$pkgdir" .
	make OGDF tests
	cd doc && ./build-ogdf-docs.sh
}

package_ogdf-snapshot() {
	cd "$srcdir/OGDF-snapshot"

	install -Dm644 libOGDF.a "$pkgdir/usr/lib/libOGDF.a"
	install -Dm644 libCOIN.a "$pkgdir/usr/lib/libCOIN.a"

	mkdir -p "$pkgdir/usr"
	cp -r include "$pkgdir/usr"
}

package_ogdf-snapshot-docs() {
	arch=('any')

	cd "$srcdir/OGDF-snapshot"

	mkdir -p "$pkgdir/usr/share/doc/$pkgbase"
	cp -r doc/* "$pkgdir/usr/share/doc/$pkgbase"
	rm "$pkgdir/usr/share/doc/$pkgbase/build-ogdf-docs.sh"
}

check() {
	cd "$srcdir/OGDF-snapshot"

	# Skip repeated failing GraphCopy test (randomness issues?)
	./tests --skip="works using source and target"
}