# $Id$
# vim:set ft=sh:
# Maintainer: Andreas Baumann <mail AT andreasbaumann DOT cc >
# based on opera PKGBUILD by:
# Maintainer: BlackEagle < ike DOT devolder AT gmail DOT com >
# Contributor: Bartłomiej Piotrowski <barthalion@gmail.com>
# Contributor: Mateusz Herych <heniekk@gmail.com>
# Contributor: ruario <ruario AT opera DOT com>
# Contributor: Daniel Isenmann <daniel AT archlinux DOT org>
# Contributor: dorphell <dorphell AT archlinux DOT org>
# Contributor: Sigitas Mazaliauskas <sigis AT gmail DOT com>
# Contributor: eworm

pkgname=opera32
_pkgname=opera
pkgver=45.0.2552.898
pkgrel=1
pkgdesc="A fast and secure web browser"
url="http://www.opera.com/"
options=(!strip !zipman)
license=('custom:opera')
backup=("etc/$pkgname/default")
arch=('i686')
depends=('gtk3' 'alsa-lib' 'libnotify' 'gconf' 'curl' 'nss' 'libcups' 'libxss' 'ttf-font' 'desktop-file-utils' 'shared-mime-info' 'hicolor-icon-theme')
comflicts=('opera')
optdepends=(
    'opera-ffmpeg-codecs: playback of proprietary video/audio (AUR)'
    'pepper-flash: flash support'
    'upower: opera battery save'
)
source=(
    "https://get.geo.opera.com/pub/${_pkgname}/desktop/${pkgver}/linux/${_pkgname}-stable_${pkgver}_i386.deb"
    "opera"
    "default"
    'eula.html'
    'terms.html'
    'privacy.html'
)
sha512sums=('913d5a0be0ac154b7340dab8580d77b95234812a0a4acb016e5e19bfba8b4e0c59df0dca4db5e9ccd6ce5f73a3f5dccea8f027d9620bd004adb64c67ce9268df'
            '7e854e4c972785b8941f60117fbe4b88baeb8d7ca845ef2e10e8064043411da73821ba1ab0068df61e902f242a3ce355b51ffa9eab5397ff3ae3b5defd1be496'
            'ddb1773877fcfd7d9674e63263a80f9dd5a3ba414cda4cc6c411c88d49c1d5175eede66d9362558ddd53c928c723101e4e110479ae88b8aec4d2366ec179297f'
            '285a0633e5863ec9c9af99138ff0b59da155a2dd72a340e784e53de3e801029eb6ca2e4b38846592b85b9f8b99dcb6f6eedbed273057a9216abe31c396d9f28a'
            '444e27eb486d80fbe3027c10e21b9e18a56de62d218ec5ca26d3a50847567ae9b8233dd1dd9a91efb697822c28c245caa6f28bcdc2ddcdf8a32067ae5a339ace'
            '9fd239d630f183147ff824c8ce87705e1a919e33b3d912f6871b5e68e123be7f843ffef2e3f2835fecc676ea2f548150eb06f154830cf865bd3392188b008671')

prepare() {
    sed -e "s/%pkgname%/$_pkgname/g" -i "$srcdir/opera"
    sed -e "s/%operabin%/$_pkgname\/$_pkgname/g" \
        -i "$srcdir/opera"

}

package() {
    tar -xf data.tar.xz --exclude=usr/share/{lintian,menu} -C "$pkgdir/"

    # get rid of the extra subfolder {i386,x86_64}-linux-gnu
    (
        cd "$pkgdir/usr/lib/"*-linux-gnu/
        mv "$_pkgname" ../
    )
    rm -rf "$pkgdir/usr/lib/"*-linux-gnu

    # suid opera_sandbox
    chmod 4755 "$pkgdir/usr/lib/$_pkgname/opera_sandbox"

    # install default options
    install -Dm644 "$srcdir/default" "$pkgdir/etc/$_pkgname/default"

    # install opera wrapper
    rm "$pkgdir/usr/bin/$_pkgname"
    install -Dm755 "$srcdir/opera" "$pkgdir/usr/bin/$_pkgname"

    # license
    install -Dm644 \
        "$pkgdir/usr/share/doc/${_pkgname}-stable/copyright" \
        "$pkgdir/usr/share/licenses/$_pkgname/copyright"

    # eula
    install -Dm644 \
        "$srcdir/eula.html" \
        "$pkgdir/usr/share/licenses/$_pkgname/eula.html"

    # terms
    install -Dm644 \
        "$srcdir/terms.html" \
        "$pkgdir/usr/share/licenses/$_pkgname/terms.html"

    # privacy
    install -Dm644 \
        "$srcdir/privacy.html" \
        "$pkgdir/usr/share/licenses/$_pkgname/privacy.html"
}