# Maintainer: Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Contributor: Brandon Andrews <bsa@bsa.isa-geek.com>
# Contributor: Mael Kerbiriou <mael.kerbiriouATfreeDOTfr>
pkgname=pfstools
pkgver=2.0.6
pkgrel=1
pkgdesc="Set of command line programs for reading, writing and manipulating high-dynamic range (HDR) images"
arch=('i686' 'x86_64')
url="http://pfstools.sourceforge.net/"
license=('LGPL2.1')
depends=('gcc-libs')
provides=('pfscalibration' 'pfstmo')
conflicts=('pfscalibration' 'pfstmo')
optdepends=('freeglut: OpenGL image viewer' 'glu: OpenGL image viewer' \
            'qt4: Qt GUI' \
            'opencv: pfsalign' \
            'openexr: OpenEXR support' \
            'imagemagick: ImageMagick support' \
            'netpbm: PBM support' \
            'dcraw: RAW support' \
            'gsl: mantiuk08 tone mapping operator' \
            'fftw: durand02,fattal02,ferradans11 tone mapping operators')
makedepends=('cmake' \
             'openexr' 'imagemagick' 'libtiff' 'netpbm' \
             'gsl' 'fftw' 'libexif' 'opencv'
             'freeglut' 'glu' 'qt4')
options=(!libtool)
source=(http://downloads.sourceforge.net/pfstools/$pkgname-$pkgver.tgz \
        opencv3.patch)
md5sums=('c3148ed11e562c30a0fd65d114cf2de2'
         '8bb92632fc2d8887a5f4aa03f6ee6636')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"

  patch -Np1 < "$srcdir/opencv3.patch"
}

build() {
  mkdir -p "$srcdir/build"
  cd "$srcdir/build"

  cmake "$srcdir/$pkgname-$pkgver" \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DWITH_Octave=OFF # disable octave, as it breaks build

  make
}

package() {
  cd "$srcdir/build"
  make DESTDIR="$pkgdir/" install
}