# Maintainer: fkobayashi <see name left ＠ 数学 (but in english) dot ubc.ca
# Maintainer: Caleb Maclennan <caleb@alerque.com>

pkgname=plom
pkgver=0.15.2
pkgrel=1
pkgdesc='Paperless open marking'
arch=(any)
url="https://gitlab.com/$pkgname/$pkgname"
license=(AGPL-3.0-only)
_pydeps=(aiohttp
         arrow
         beautifulsoup4
         canvasapi
         cryptography
         debugpy
         django
         django-braces
         django-filter
         django-htmx
         django-huey
         django-humanize
         django-mathfilters
         django-polymorphic
         django-reset-migrations
         djangorestframework
         django-session-timeout
         exif
         file-magic
         fonttools
         imutils
         matplotlib
         model-bakery
         numpy
         # opencv-python-headless
         packaging
         pandas
         passlib
         peewee
         pillow
         platformdirs
         psycopg2 # psycopg2-binary
         pymupdf
         pymysql
         pyqt6
         # pyqt6-qt6
         pyqt6-sip
         pytest-qt
         random-username
         requests
         requests-toolbelt
         scikit-learn
         scipy
         seaborn
         segno
         stdiomask
         tabulate
         tomli
         tomlkit
         tqdm
         urllib3
         weasyprint
         whitenoise
         zipfly
         zxing-cpp)
depends=(opencv
         gunicorn
         python
         "${_pydeps[@]/#/python-}"
         pyzbar)
makedepends=(python-{build,installer,wheel}
             python-setuptools)
checkdepends=(python-pytest)
_archive="$pkgname-$pkgver"
source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$_archive.tar.gz")
sha256sums=('f93761fc7ddcdb5cd206d5f87f1c1140d2ed767d07d90799134d860f993bc350')

build() {
	cd "$_archive"
	python -m build -wn
}

check() {
	cd "$_archive"
	# Tests are not all passing yet, I think because the test suite layout is messed up.
	# I'm giving it a pass at least until we figure out *why* it is failing.
	pytest -l --pyargs "$pkgname" ||:
}

package() {
	cd "$_archive"
	python -m installer -d "$pkgdir" dist/*.whl
}