# Maintainer: spider-mario <spidermario@free.fr>

_pkgname=amply
pkgbase=python-amply
pkgname=(python-amply python2-amply)
pkgver=0.1.4
pkgrel=1
pkgdesc="A Python package for AMPL/GMPL datafile parsing"
arch=("any")
license=("EPL")
url="http://github.com/willu47/amply"
makedepends=('python-pip' 'python-wheel' 'python2-pip' 'python2-wheel')
source=("https://files.pythonhosted.org/packages/source/${_pkgname::1}/$_pkgname/$_pkgname-$pkgver.tar.gz")
b2sums=('78ae51f18355968c7713351267fe8a60adc797c9e0e37092f538935026898b51413f346a0faecc748a290f3fd3e4c313cfab6d0ddacfe34f76ecdb4ecd562ffb')

prepare() {
	for _python in python python2; do
		rm -fr $_python-amply
		cp -r $_pkgname-$pkgver $_python-amply
	done
}

build() {
	for _python in python python2; do
		pushd $_python-amply
		$_python setup.py build
		popd
	done
}

_package_for_python_version() {
	_python="$1"

	cd $_python-amply

	$_python setup.py install --prefix=/usr --root="$pkgdir" --optimize=1 --skip-build
}

package_python-amply() {
	depends=('python-docutils' 'python-pyparsing')
	_package_for_python_version python
}

package_python2-amply() {
	depends=('python2-docutils' 'python2-pyparsing')
	_package_for_python_version python2
}