# Contributor: Jakob Gahde <j5lx@fmail.co.uk>
# Contributor: Johannes Löthberg <johannes@kyriasis.com>
# Contributor: Sébastien Luttringer
# Contributor: Angel Velasquez <angvp@archlinux.org>
# Contributor: Fabio Volpe <volpefabio@gmail.com>

pkgbase=python-sphinx1
pkgname=('python-sphinx1' 'python2-sphinx1')
pkgver=1.8.5
pkgrel=1

arch=('any')
url='http://www.sphinx-doc.org/'
license=('BSD')

makedepends=(
  'python-setuptools'
  'python-docutils'
  'python-jinja'
  'python-pygments'
  'python-six'
  'python-imagesize'
  'python-sphinxcontrib-websupport'
  'python-sqlalchemy'
  'python-whoosh'
  'python2-setuptools'
  'python2-docutils'
  'python2-jinja'
  'python2-pygments'
  'python2-six'
  'python2-imagesize'
  'python2-sphinxcontrib-websupport'
  'python2-sqlalchemy'
  'python2-whoosh'
  'python2-typing'
)

checkdepends=(
  'texlive-latexextra'
  'python-nose' 'python2-nose'
  'python-snowballstemmer' 'python2-snowballstemmer'
  'python-babel' 'python2-babel'
  'python-sphinx-alabaster-theme' 'python2-sphinx-alabaster-theme'
  'python-sphinx_rtd_theme' 'python2-sphinx_rtd_theme'
  'python-mock' 'python2-mock'
  'python-html5lib' 'python2-html5lib'
  'python-requests' 'python2-requests'
  'python2-pytest' 'python-pytest'
  'python2-enum34'
  'python-sphinxcontrib-websupport' 'python2-sphinxcontrib-websupport'
  'imagemagick' 'librsvg'
)

source=("https://pypi.org/packages/source/S/Sphinx/Sphinx-$pkgver.tar.gz"{,.asc})

validpgpkeys=('8A11B79A5D0D749A66F0A030102C2C17498D6B9E'
              'E9BEABB07E7B9CC3F56E62C91425F8CE5EBA0E07')
sha512sums=('d7e6a7a6186d1d4e4de0233fb6859da1ef3e02f628512ff9096ef4775b9fb8589edb9052d752925d7a2f1cb7901291af96b5036a5d00f5f58966609bd42872f4'
            'SKIP')

prepare() {
  # souce duplication is required because makefile modify source code
  # setyp.py --build tricks don't works well
  cp -a Sphinx-$pkgver Sphinx-${pkgver}2
  # change python2 interpreter
  find Sphinx-${pkgver}2 -type f -exec \
    sed -i '1s,^#! \?/usr/bin/\(env \|\)python$,#!/usr/bin/python2,' {} \;
  # change sphinx-binaries name in source code
  find Sphinx-${pkgver}2 -type f -name '*.py' -exec \
    sed -ri 's,(sphinx-(:?build|apidoc|autogen|quickstart)),\12,' {} \;
}

build() {
  msg2 'Python 3 version'
  cd "$srcdir"/Sphinx-$pkgver
  make PYTHON=python3 build

  msg2 'Python 2 version'
  cd "$srcdir"/Sphinx-${pkgver}2
  make PYTHON=python2 build
}

#check() {
#  msg2 'Python 3 version'
#  cd "$srcdir"/Sphinx-$pkgver
#  LC_ALL="en_US.UTF-8" make PYTHON=python3 test
#  rm -r tests
#
#  msg2 'Python 2 version'
#  cd "$srcdir"/Sphinx-${pkgver}2
#  LC_ALL="en_US.UTF-8" make PYTHON=python2 test
#  rm -r tests
#}

package_python-sphinx1() {
  pkgdesc='Python3 documentation generator (version 1)'
  depends=(
    'python-setuptools'
    'python-jinja'
    'python-pygments'
    'python-docutils'
    'python-sphinx_rtd_theme'
    'python-sphinx-alabaster-theme'
    'python-babel'
    'python-snowballstemmer'
    'python-six'
    'python-imagesize'
    'python-requests'
    'python-sphinxcontrib-websupport'
    'python-sqlalchemy'
    'python-whoosh'
  )
  optdepends=('texlive-latexextra: for generation of PDF documentation'
              'imagemagick: ext.imageconverter')

  provides=("python-sphinx=$pkgver")
  conflicts=('python-sphinx')

  cd Sphinx-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1

  install -Dm644 "$srcdir"/Sphinx-$pkgver/LICENSE "$pkgdir"/usr/share/licenses/python-sphinx1/LICENSE
}

package_python2-sphinx1() {
  pkgdesc='Python2 documentation generator (version 1)'
  depends=(
    'python2-setuptools'
    'python2-jinja'
    'python2-pygments'
    'python2-docutils'
    'python2-sphinx_rtd_theme'
    'python2-sphinx-alabaster-theme'
    'python2-babel'
    'python2-snowballstemmer'
    'python2-six'
    'python2-imagesize'
    'python2-requests'
    'python2-sphinxcontrib-websupport'
    'python2-sqlalchemy'
    'python2-whoosh'
    'python2-typing'
  )
  optdepends=('texlive-latexextra: for generation of PDF documentation'
              'imagemagick: ext.imageconverter')

  provides=("python2-sphinx=$pkgver")
  conflicts=('python2-sphinx')

  cd Sphinx-${pkgver}2
  python2 setup.py install --root="$pkgdir" --optimize=1

  install -Dm644 "$srcdir"/Sphinx-$pkgver/LICENSE "$pkgdir"/usr/share/licenses/python2-sphinx1/LICENSE
}

# vim:set ts=2 sw=2 et: