# Maintainer: Florian Bruhin (The Compiler) <archlinux.org@the-compiler.org>
# vim: set ts=2 sw=2 et ft=sh:

pkgname=qutebrowser-git
pkgver=r3206.3622f35
pkgrel=2
pkgdesc="A keyboard-driven, vim-like browser based on PyQt5 and QtWebKit"
arch=(any)
url="http://www.qutebrowser.org/"
license=('GPL')
depends=('python>=3.4' 'python-setuptools' 'python-pyqt5>=5.2' 'qt5-base>=5.2'
         'qt5-webkit>=5.2' 'libxkbcommon-x11' 'python-pypeg2' 'python-jinja'
         'python-pygments')
makedepends=('asciidoc')
optdepends=(
  'python-colorlog: colored logging output'
  'gst-libav: media playback'
  'gst-plugins-base: media playback'
  'gst-plugins-good: media playback'
  'gst-plugins-bad: media playback'
  'gst-plugins-ugly: media playback'
)
options=(!emptydirs)
source=('git+https://github.com/The-Compiler/qutebrowser.git')
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/qutebrowser"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
  cd "$srcdir/qutebrowser"
  python scripts/asciidoc2html.py
  python setup.py install --root="$pkgdir/" --optimize=1
  a2x -f manpage doc/qutebrowser.1.asciidoc
  install -Dm644 doc/qutebrowser.1 "$pkgdir/usr/share/man/man1/qutebrowser.1"
}