# See http://wiki.archlinux.org/index.php/VCS_PKGBUILD_Guidelines
# for more information on packaging from GIT sources.

# Maintainer: Vincenzo Maffione <v.maffione@gmail.com>
pkgname=rlite-git
pkgver=r3736.d74553e7
pkgrel=1
pkgdesc="Recursive InterNetwork Architecture (RINA) user/kernel prototype written in C/C++"
arch=('x86_64' 'i686' 'arm')
license=('GPL' 'LGPL')
depends=('linux' 'protobuf' 'python')
makedepends=('git' 'linux-headers' 'fakeroot' 'cmake')
install="rlite.install"
source=("rlite.install" "git+https://github.com/vmaffione/rlite.git")
noextract=()
md5sums=("047aa5adec4c52ddbf86d12dbf300f71" "SKIP")

_gitname="rlite"

pkgver() {
        cd "$srcdir/${pkgname%-git}"
        printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    RKVER=$(uname -r | sed 's|-.*||g')
    KMAJVER=$(echo "$RKVER" | sed 's|\.[0-9]\+$||g')
    msg "Building on kernel ${RKVER}..."

    cd "$srcdir/$_gitname"
    ./configure --prefix "$pkgdir" --libmodprefix /usr
    make
    msg "Build complete"
}

package() {
    make -C "$srcdir/$_gitname" install

    # Install other system files
    mkdir -p "$pkgdir/run/rlite"
    mkdir -p "$pkgdir/usr/lib/systemd/system/"
    mkdir -p "$pkgdir/etc/modules-load.d"
    cp $srcdir/$_gitname/archlinux/rlite.service "$pkgdir/usr/lib/systemd/system/"
    cp $srcdir/$_gitname/archlinux/rlite.conf "$pkgdir/etc/modules-load.d"

    # Remove the files generated by depmod. We will run depmod out of the
    # fakeroot environment (see netmap.install).
    rm ${pkgdir}/usr/lib/modules/`uname -r`/modules.*
}

# vim:set ts=2 sw=2 et: