# Maintainer: graysky <graysky AT archlinux DOT us>

pkgname=rtl8192du-git
_pkgname=rtl8192du
pkgver=d5056bd
pkgrel=4
pkgdesc="Kernel module for Realtek RTL8192DU USB wireless devices."
arch=('x86_64')
url="https://github.com/lwfinger/rtl8192du"
license=('GPL')
_extramodules="extramodules-ARCH"
depends=('linux>=5.0' 'linux<5.1')
makedepends=('linux-headers>=5.0' 'git')
source=("git://github.com/lwfinger/$_pkgname.git"
00-unfuck-build-for-linux5.0.patch::https://github.com/lwfinger/rtl8192du/pull/69/commits/ddbc81d4c1c172742e5a6f0cabdfef50cb9ba491.patch)
sha256sums=('SKIP'
            '55c30249976b7c360ba193b3e61fd1c921a87708bea9ba68a3bf5b8906e1b47d')

_kernver="$(cat /usr/lib/modules/${_extramodules}/version)"

pkgver() {
  cd "$_pkgname"
  git describe --always | sed 's|-|.|g'
}

prepare() {

  cd "$_pkgname"

  # fixup for Arch
  #
  # 1) reference the static kernel ver not the running one
  # 2) remove the depmod command which we do in the postinstall
  sed -i -e "/^KSRC/ s,\$(KVER),$_kernver," \
    -i -e '/depmod/d' Makefile

  patch -Np1 -i ../00-unfuck-build-for-linux5.0.patch
}

build() {
  cd "$_pkgname"
  make INSTALL_PREFIX=/usr
  gzip -9 8192du.ko
}

package() {
  # module
  install -d "$pkgdir/usr/lib/modules/${_extramodules}/kernel/drivers/net/wireless"
  install -m644 "$srcdir/$_pkgname/8192du.ko.gz" \
    "$pkgdir/usr/lib/modules/${_extramodules}/kernel/drivers/net/wireless/8192du.ko.gz"

  # firmware
  install -d "$pkgdir/usr/lib/firmware/rtlwifi"
  install -m644 "$srcdir/$_pkgname/rtl8192dufw.bin" \
    "$pkgdir/usr/lib/firmware/rtlwifi/rtl8192dufw.bin"
  install -m644 "$srcdir/$_pkgname/rtl8192dufw_wol.bin" \
    "$pkgdir/usr/lib/firmware/rtlwifi/rtl8192dufw_wol.bin"
}

# vim:set ts=2 sw=2 et: