# Contributor: Emanuel Fernandes <efernandes@tektorque.com>
# Maintainer: tee < teeaur at duck dot com >

_channel=stable
pkgname="tws"
_pkgver=10.19
pkgver="$_pkgver.2l"
pkgrel=1
pkgdesc='IntereactiveBrokers Trader Workstation'
arch=('x86_64')
url='https://www.interactivebrokers.com/en/trading/tws.php#tws-software'
license=('custom')
depends=()
optdepends=()
source=("https://download2.interactivebrokers.com/installers/$pkgname/$_channel-standalone/$pkgname-$_channel-standalone-linux-x64.sh")
b2sums=('e00803aff1d384231f55c390cec9d200b86aa62be5ecd0a6f28bff479ead66f38ff167a525321988ae36cfb31980f1b3e65dd55d8ca18d243a276cb986111cc9')

prepare() {
    # unattended mode
    sh "./$pkgname-$_channel-standalone-linux-x64.sh" -q -dir "$srcdir/$pkgname" -overwrite
    sed -i "s|$srcdir/$pkgname|/opt/$pkgname|" \
        "$srcdir/$pkgname/tws.vmoptions" \
        "$srcdir/$pkgname/Trader Workstation $_pkgver.desktop" \
        "$srcdir/$pkgname/.install4j/response.varfile" \
        "$srcdir/$pkgname/.install4j/install.prop" \
        "$srcdir/$pkgname/.install4j/files.log" \
        "$srcdir/$pkgname/.install4j/installation.log" \
        "$srcdir/$pkgname/.install4j/install4j_1m87msa-tws.desktop"
}

package() {
    cd ${srcdir}

    install -d "$pkgdir/opt/$pkgname"
    cp -a $srcdir/$pkgname/. "$pkgdir/opt/$pkgname"

    chmod 755 "$pkgdir/opt/$pkgname"

    install -d "$pkgdir"/usr/{bin,share/{pixmaps,applications}}
    ln -s /opt/$pkgname/tws "$pkgdir"/usr/bin/$pkgname
    ln -s /opt/$pkgname/.install4/tws.png "$pkgdir"/usr/share/pixmaps/$pkgname.png
    ln -s "/opt/$pkgname/Trader Workstation $_pkgver.desktop" "$pkgdir"/usr/share/applications/$pkgname.desktop
}
# vim:set noet sts=0 sw=4 ts=4 ft=PKGBUILD: