# Maintainer: Oscar Morante <spacepluk at gmail dot com>

_version=2018.2.0
_build=b2
_buildtag=20180501
_randomstring=7b8938f7fa83
_prefix=/opt/UnityBeta
_unitydownloads="http://beta.unity3d.com/download/${_randomstring}"
#_keepdownloads=yes

pkgname=unity-editor-beta-windows
pkgver=${_version}${_build}+${_buildtag}
pkgrel=1
pkgdesc="Allows building your Unity projects for the Windows platform"
arch=('x86_64')
url='https://unity3d.com/'
license=('custom')
depends=('unity-editor-beta')
makedepends=('gtk2' 'libsoup' 'libarchive')
source=("${_unitydownloads}/UnitySetup-${_version}${_build}")
sha1sums=('42112f9cc81bc941f88230631547b65daed008cc')
options=(!strip)
PKGEXT='.pkg.tar' # Prevent compressing of the final package

unity-setup() {
  ./UnitySetup-${_version}${_build} \
    --download-location="${startdir}" \
    --install-location="${pkgdir}${_prefix}" \
    --unattended $@
}

extract-component() {
  msg2 "Extracting $1..."
  yes | unity-setup --components=$1 > "/tmp/$1.log"
}

prepare() {
  chmod +x "${srcdir}/UnitySetup-${_version}${_build}"
}

package_unity-editor-beta-windows() {
  mkdir -p "${pkgdir}${_prefix}"
  extract-component Windows-Mono

  if [ -z "${_keepdownloads}" ]; then
    rm "${startdir}/UnitySetup-Windows-Mono-Support-for-Editor-${_version}${_build}.pkg"
  fi
}