path: root/PKGBUILD.aarch64_ada_bootstrap

# Maintainer: Wilken Gottwalt <wilken dot gottwalt at posteo dot net>

pkgbase=gcc-snapshot
pkgname=({gcc,gcc-libs,gcc-ada,gcc-d}-snapshot)
pkgver=15.1.0
_majorver=${pkgver//.*}
_gnatarch=aarch64-linux-gnu
_gnatver=15.1.0-1
_gmpver=6.3.0
_mpcver=1.3.1
_mpfrver=4.2.2
pkgrel=1
pkgdesc='The GNU Compiler Collection (Ada aarch64 bootstrap)'
arch=(aarch64)
license=(GPL-3.0-with-GCC-exception GFDL-1.3-or-later)
url='https://gcc.gnu.org'
makedepends=(binutils doxygen gcc-d git python rust zstd)
checkdepends=(dejagnu expect inetutils python-pytest tcl)
options=(!emptydirs !lto)
_libdir=usr/lib/gcc/${CHOST}/${pkgver}
source=(https://ftp.fu-berlin.de/unix/languages/gcc/releases/gcc-${pkgver}/gcc-${pkgver}.tar.xz
        https://github.com/alire-project/GNAT-FSF-builds/releases/download/gnat-${_gnatver}/gnat-aarch64-linux-${_gnatver}.tar.gz
        git+https://repo.or.cz/isl.git#branch=maint
        https://gmplib.org/download/gmp/gmp-${_gmpver}.tar.xz{,.sig}
        https://ftp.gnu.org/gnu/mpc/mpc-${_mpcver}.tar.gz
        https://www.mpfr.org/mpfr-${_mpfrver}/mpfr-${_mpfrver}.tar.xz{,.asc}
        0002-libgccjit-Remove-obsolete-texinfo-statements.patch
        c89
        c99
        gcc-ada-repro.patch)
validpgpkeys=(F3691687D867B81B51CE07D9BBE43771487328A9  # bpiotrowski@archlinux.org
              86CFFCA918CF3AF47147588051E8B148A9999C34  # evangelos@foutrelis.com
              13975A70E63C361C73AE69EF6EEB81F8981C74C7  # richard.guenther@gmail.com
              D3A93CAD751C2AF4F8C7AD516C35B99309B5FA62  # Jakub Jelinek <jakub@redhat.com>
              343C2FF0FBEE5EC2EDBEF399F3599FF828C67298  # nisse@lysator.liu.se
              A534BE3F83E241D918280AEB5831D11A0D4DB02A) # vincent@vinc17.net
sha256sums=('e2b09ec21660f01fecffb715e0120265216943f038d0e48a9868713e54f06cea'
            'e92de20420b1ee7b4277d37311094e89d0677af88e9ffe2540fe2acc3c25386d'
            'SKIP'
            'a3c2b80201b89e68616f4ad30bc66aee4927c3ce50e33929ca819d5c43538898'
            'SKIP'
            'ab642492f5cf882b74aa0cb730cd410a81edcdbec895183ce930e706c1c759b8'
            'b67ba0383ef7e8a8563734e2e889ef5ec3c3b898a01d00fa0a6869ad81c6ce01'
            'SKIP'
            '08ee6d267261aeaeadc117b7fc1cdfcbb60ffb9ae76728f33d6fcc60b0e8f240'
            'de48736f6e4153f03d0a5d38ceb6c6fdb7f054e8f47ddd6af0a3dbf14f27b931'
            '2513c6d9984dd0a2058557bf00f06d8d5181734e41dcfe07be7ed86f2959622a'
            '1773f5137f08ac1f48f0f7297e324d5d868d55201c03068670ee4602babdef2f')

prepare() {
  if [ ! -d gcc ]; then
    ln -s gcc-${pkgver} gcc
  fi

  if [ ! -d gnat ]; then
    ln -s gnat-aarch64-linux-${_gnatver} gnat
  fi

  rm -f ${srcdir}/gnat/lib/gcc/${_gnatarch}/${_gnatver//-*}/include-fixed/pthread.h

  cd gcc
  mv ../isl isl
  mv ../gmp-${_gmpver} gmp
  mv ../mpc-${_mpcver} mpc
  mv ../mpfr-${_mpfrver} mpfr
  echo "${pkgver}" >gcc/BASE-VER

  sed -i 's@\./fixinc\.sh@-c true@' gcc/Makefile.in
  sed -i '/lp64=/s/lib64/lib/' gcc/config/aarch64/t-aarch64-linux

  patch -Np0 -i ${srcdir}/gcc-ada-repro.patch
  patch -Np1 -i ${srcdir}/0002-libgccjit-Remove-obsolete-texinfo-statements.patch

  mkdir -p ${srcdir}/gcc-build
}

build() {
  export PATH=${srcdir}/gnat-aarch64-linux-${_gnatver}/bin:${PATH}

  local _confflags=(
    --prefix=/usr
    --libdir=/usr/lib
    --libexecdir=/usr/lib
    --mandir=/usr/share/man
    --infodir=/usr/share/info
    --with-bugurl=https://aur.archlinux.org/packages/gcc-snapshot
    --with-build-config=bootstrap-lto
    --with-linker-hash-style=gnu
    --with-system-zlib
    --with-isl-include=${srcdir}/gcc-${_pkgver}/isl/include
    --enable-__cxa_atexit
    --enable-cet=auto
    --enable-checking=release
    --enable-clocale=gnu
    --enable-default-pie
    --enable-default-ssp
    --enable-gnu-indirect-function
    --enable-gnu-unique-object
    --enable-libstdcxx-backtrace
    --enable-link-serialization=1
    --enable-linker-build-id
    --enable-lto
    --enable-plugin
    --enable-shared
    --enable-threads=posix
    --disable-libssp
    --disable-libstdcxx-pch
    --disable-multilib
    --disable-werror
  )

  cd gcc-build

  CFLAGS=${CFLAGS/-Werror=format-security/}
  CXXFLAGS=${CXXFLAGS/-Werror=format-security/}

  ${srcdir}/gcc/configure \
    --enable-languages=ada,c,c++,d,lto \
    --enable-bootstrap \
    "${_confflags[@]:?_confflags unset}"

  make -O "STAGE1_CFLAGS=-Os" "STAGE2_CFLAGS=-Os" "STAGE3_CFLAGS=-Os" "STAGE4_CFLAGS=-Os" \
          "BOOT_CFLAGS=${CFLAGS}" "BOOT_LDFLAGS=${LDFLAGS}" "LDFLAGS_FOR_TARGET=${LDFLAGS}" \
          bootstrap

  make -O -C ${CHOST}/libstdc++-v3/doc doc-man-doxygen

  make -O "STAGE1_CFLAGS=-Os" "STAGE2_CFLAGS=-Os" "STAGE3_CFLAGS=-Os" "STAGE4_CFLAGS=-Os" \
          "BOOT_CFLAGS=${CFLAGS}" "BOOT_LDFLAGS=${LDFLAGS}" "LDFLAGS_FOR_TARGET=${LDFLAGS}" \
          all-gcc
}

check() {
  cd gcc-build

  sed -i '/maybe-check-target-libphobos \\/d' Makefile

  make -O -k check || true
  ${srcdir}/gcc/contrib/test_summary
}

package_gcc-libs-snapshot() {
  pkgdesc='Runtime libraries shipped by GCC (snapshot)'
  depends=("glibc>=2.40")
  options=(!emptydirs lto strip)
  provides=(${pkgname} "gcc-libs=${pkgver}-${pkgrel}" libgphobos.so libubsan.so libasan.so libtsan.so liblsan.so)
  replaces=(${pkgname} gcc-libs libgphobos)
  conflicts=(gcc-libs)

  cd gcc-build

  make -C ${CHOST}/libgcc DESTDIR=${pkgdir} install-shared

  rm -f ${pkgdir}/${_libdir}/libgcc_eh.a

  for lib in libatomic libgomp libitm libquadmath \
             libsanitizer/{a,l,ub,t}san libstdc++-v3/src libvtv
  do
    make -C ${CHOST}/${lib} DESTDIR=${pkgdir} install-toolexeclibLTLIBRARIES
  done

  make -C ${CHOST}/libstdc++-v3/po DESTDIR=${pkgdir} install
  make -C ${CHOST}/libphobos DESTDIR=${pkgdir} install

  rm -rf ${pkgdir}/${_libdir}/include/d/ ${pkgdir}/usr/lib/libgphobos.spec

  for lib in libgomp libitm libquadmath
  do
    make -C ${CHOST}/${lib} DESTDIR=${pkgdir} install-info
  done

  rm -rf ${pkgdir}/usr/lib/gcc

  install -Dm644 ${srcdir}/gcc/COPYING.RUNTIME \
    ${pkgdir}/usr/share/licenses/gcc-libs/RUNTIME.LIBRARY.EXCEPTION
}

package_gcc-snapshot() {
  pkgdesc='The GNU Compiler Collection - C and C++ frontends (snapshot)'
  depends=("gcc-libs-snapshot=${pkgver}-${pkgrel}" "binutils>=2.40" zstd)
  provides=(${pkgname} gcc)
  replaces=(${pkgname} gcc)
  conflicts=(gcc)
  options=(!emptydirs lto strip staticlibs)

  cd gcc-build

  make -C gcc DESTDIR=${pkgdir} install-driver install-cpp install-gcc-ar c++.install-common \
                                install-headers install-plugin install-lto-wrapper

  install -m755 -t ${pkgdir}/usr/bin/ gcc/gcov{,-tool}
  install -m755 -t ${pkgdir}/${_libdir}/ gcc/{cc1,cc1plus,collect2,lto1}

  make -C ${CHOST}/libgcc DESTDIR=${pkgdir} install

  rm -f ${pkgdir}/usr/lib/libgcc_s.so*

  make -C ${CHOST}/libstdc++-v3/src DESTDIR=${pkgdir} install
  make -C ${CHOST}/libstdc++-v3/include DESTDIR=${pkgdir} install
  make -C ${CHOST}/libstdc++-v3/libsupc++ DESTDIR=${pkgdir} install
  make -C ${CHOST}/libstdc++-v3/python DESTDIR=${pkgdir} install
  make DESTDIR=${pkgdir} install-libcc1

  install -d ${pkgdir}/usr/share/gdb/auto-load/usr/lib
  mv ${pkgdir}/usr/lib/libstdc++.so.6.*-gdb.py ${pkgdir}/usr/share/gdb/auto-load/usr/lib/

  rm ${pkgdir}/usr/lib/libstdc++.so*

  make DESTDIR=${pkgdir} install-fixincludes
  make -C gcc DESTDIR=${pkgdir} install-mkheaders
  make -C lto-plugin DESTDIR=${pkgdir} install

  install -dm755 ${pkgdir}/usr/lib/bfd-plugins/
  ln -s /${_libdir}/liblto_plugin.so ${pkgdir}/usr/lib/bfd-plugins/

  make -C ${CHOST}/libgomp DESTDIR=${pkgdir} install-nodist_{libsubinclude,toolexeclib}HEADERS
  make -C ${CHOST}/libitm DESTDIR=${pkgdir} install-nodist_toolexeclibHEADERS
  make -C ${CHOST}/libquadmath DESTDIR=${pkgdir} install-nodist_libsubincludeHEADERS
  make -C ${CHOST}/libsanitizer DESTDIR=${pkgdir} install-nodist_{saninclude,toolexeclib}HEADERS
  make -C ${CHOST}/libsanitizer/asan DESTDIR=${pkgdir} install-nodist_toolexeclibHEADERS
  make -C ${CHOST}/libsanitizer/tsan DESTDIR=${pkgdir} install-nodist_toolexeclibHEADERS
  make -C ${CHOST}/libsanitizer/lsan DESTDIR=${pkgdir} install-nodist_toolexeclibHEADERS
  make -C gcc DESTDIR=${pkgdir} install-man install-info

  rm -f ${pkgdir}/usr/share/man/man1/gdc*
  rm -f ${pkgdir}/usr/share/info/{gnat-style,gnat_rm,gnat_ugn,lto-dump,gdc}*
  rm -f ${pkgdir}/usr/share/info/gdc*

  make -C libcpp DESTDIR=${pkgdir} install
  make -C gcc DESTDIR=${pkgdir} install-po

  ln -s gcc ${pkgdir}/usr/bin/cc

  for binary in {c++,g++,gcc,gcc-ar,gcc-nm,gcc-ranlib}
  do
    if [ ! -f ${pkgdir}/usr/bin/${CHOST}-${binary} ]; then
      ln -s /usr/bin/${binary} ${pkgdir}/usr/bin/${CHOST}-${binary}
    fi
  done

  install -Dm755 ${srcdir}/c89 ${pkgdir}/usr/bin/c89
  install -Dm755 ${srcdir}/c99 ${pkgdir}/usr/bin/c99

  make -C ${CHOST}/libstdc++-v3/doc DESTDIR=${pkgdir} doc-install-man

  python -m compileall ${pkgdir}/usr/share/gcc-${pkgver%%+*}/
  python -O -m compileall ${pkgdir}/usr/share/gcc-${pkgver%%+*}/

  install -d ${pkgdir}/usr/share/licenses/${pkgname}/
  ln -s /usr/share/licenses/gcc-libs/RUNTIME.LIBRARY.EXCEPTION \
    ${pkgdir}/usr/share/licenses/${pkgname}/
}

package_gcc-ada-snapshot() {
  pkgdesc='Ada front-end for GCC (snapshot)'
  depends=("gcc-snapshot=${pkgver}-${pkgrel}")
  provides=(${pkgname}-multilib gcc-ada-multilib gcc-ada)
  replaces=(${pkgname}-multilib gcc-ada-multilib gcc-ada)
  conflicts=(gcc-ada-multilib gcc-ada)
  options=(!emptydirs lto strip staticlibs)

  cd gcc-build/gcc

  make DESTDIR=${pkgdir} ada.install-{common,info}
  install -m755 gnat1 ${pkgdir}/${_libdir}

  cd ${srcdir}/gcc-build/${CHOST}/libada
  make DESTDIR=${pkgdir} INSTALL=install INSTALL_DATA="install -m644" install-libada

  ln -s gcc ${pkgdir}/usr/bin/gnatgcc

  mv ${pkgdir}/${_libdir}/adalib/libgna{rl,t}-${_majorver}.so ${pkgdir}/usr/lib
  ln -s libgnarl-${_majorver}.so ${pkgdir}/usr/lib/libgnarl.so
  ln -s libgnat-${_majorver}.so ${pkgdir}/usr/lib/libgnat.so

  rm -f ${pkgdir}/${_libdir}/adalib/libgna{rl,t}.so

  install -d ${pkgdir}/usr/share/licenses/${pkgname}/
  ln -s /usr/share/licenses/gcc-libs/RUNTIME.LIBRARY.EXCEPTION \
    ${pkgdir}/usr/share/licenses/${pkgname}/
}

package_gcc-d-snapshot() {
  pkgdesc='D frontend for GCC (snapshot)'
  depends=("gcc-snapshot=${pkgver}-${pkgrel}")
  provides=(gcc-d gdc)
  replaces=(gcc-d gdc)
  conflicts=(gcc-d gdc)
  options=(lto strip staticlibs)

  cd gcc-build

  make -C gcc DESTDIR=${pkgdir} d.install-{common,man,info}

  install -Dm755 gcc/gdc ${pkgdir}/usr/bin/gdc
  install -Dm755 gcc/d21 ${pkgdir}/${_libdir}/d21

  make -C ${CHOST}/libphobos DESTDIR=${pkgdir} install

  rm -f ${pkgdir}/usr/lib/lib{gphobos,gdruntime}.so*

  install -d ${pkgdir}/usr/share/licenses/${pkgname}/
  ln -s /usr/share/licenses/gcc-libs/RUNTIME.LIBRARY.EXCEPTION \
    ${pkgdir}/usr/share/licenses/${pkgname}/
}