blob: 6ffdaaed28df75c82513a01a66ad77f63fcf6c8a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
|
#!/hint/bash
# Maintainer : bartus <arch-user-repoᘓbartus.33mail.com>
# Contributor: Filipe Laíns (FFY00) <filipe.lains@gmail.com>
# Contributor: Iru Cai <mytbk920423@gmail.com>
# Contributor: Alexander Hunziker <alex.hunziker@gmail.com>
# Contributor: Alessio Biancalana <dottorblaster@gmail.com>
: DISABLE_MESON="${DISABLE_MESON:=0}" # switch to autotools `makepkg DISABLE_MESON=1`
((DISABLE_MESON)) && makedepends+=('vala') || makedepends+=('meson')
pkgname=gimp-git
_pkgname=${pkgname%-git}
provides=(gimp)
conflicts=(gimp)
epoch=2
pkgver=2.99.1.r1398.f7ac033777
pkgrel=1
pkgdesc="GNU Image Manipulation Program"
arch=('i686' 'x86_64')
url="https://www.gimp.org"
license=('GPL' 'LGPL')
depends=(
'lcms2>=@_lcms_version@'
'libwmf>=@_wmf_version@'
'icu'
'enchant'
'libgexiv2>=@_gexiv2_version@'
'librsvg>=@_rsvg_version@'
'desktop-file-utils'
'libexif>=0.6.15'
'libart-lgpl>=2.3.19'
'dbus-glib'
'gtk-doc>=@_gtkdoc_version@'
'poppler-glib>=@_poppler_version@'
'poppler-data>=@_poppler_data_version@'
'openexr>=@_openexr_version@'
'mypaint-brushes1>=@_libmypaint_version@'
'babl>=@_babl_version@'
'gegl>=@_gegl_version@'
'cairo>=@_cairo_version@'
'appstream-glib>=@_appstream_glib_version@'
'gobject-introspection>=@_introspection_version@'
)
makedepends+=('git' 'intltool>=0.40.1'
'alsa-lib>=1.0.0' 'libxslt' 'glib-networking'
'alsa-lib' 'curl' 'ghostscript' 'libxpm' 'webkit2gtk'
'libheif' 'libwebp' 'libmng' 'iso-codes' 'aalib' 'zlib'
'gjs' 'python-gobject' 'luajit'
)
checkdepends=('xorg-server-xvfb')
optdepends=('gutenprint: for sophisticated printing only as gimp has built-in cups print support'
'alsa-lib: for MIDI event controller module'
'curl: for URI support'
'ghostscript: for postscript support'
'libxpm: XPM support'
'webkit2gtk: HTML renderer and web content engine'
'libheif: HEIF support'
'libwebp: WebP support'
'libmng: MNG support'
'iso-codes: Language support'
'aalib: ASCII art support'
'zlib: Compression routines'
'gjs: JavaScript scripting support'
'luajit: LUA scripting support'
)
source=('git+https://gitlab.gnome.org/GNOME/gimp.git'
'linux.gpl')
sha512sums=('SKIP'
'6f33d57f242fa8ce04b65e06a712bd54677306a45b22cb853fbe348089cd4673bd4ed91073074fe067166fe8951c370f8bbbc386783e3ed5170d52e9062666fe')
pkgver() {
# shellcheck disable=SC2183,SC2046
printf "%s.%s.%s.r%s.%s" \
$(grep -oP 'gimp_(major|minor|micro)_version\], \[\K[0-9]{1,2}' ${_pkgname}/configure.ac) \
"$(git -C $_pkgname rev-list "$(git -C $_pkgname describe --abbrev=0)"..HEAD --count)" \
"$(git -C $_pkgname log --pretty=format:'%h' -n 1)"
}
build() {
if ((DISABLE_MESON)); then
cd $_pkgname
./autogen.sh \
--prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/bin \
--enable-mp \
--enable-gimp-console \
--enable-gtk-doc \
--disable-check-update \
--disable-python \
--with-bug-report-url='https://github.com/bartoszek/AUR-gimp-git/issues' \
--with-openexr \
--without-aa
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
else
# export CFLAGS CXXFLAGS LDFLAGS
meson "${srcdir}/${_pkgname}"\
"${srcdir}/build"\
--prefix=/usr \
-Dbug-report-url='https://github.com/bartoszek/AUR-gimp-git/issues'
export NINJA_STATUS="[%p | %f<%r<%u | %cbps ] "
# shellcheck disable=SC2046 # allow MAKEFLAGS to split when passing multiple flags.
ninja $(grep -oP -- '-+[A-z]+ ?[0-9]*'<<<"${MAKEFLAGS:--j1}") -C "${srcdir}/build"
fi
}
check() {
if ((DISABLE_MESON)); then
cd $_pkgname
xvfb-run make check
# xvfb-run make distcheck
else
ninja -C "${srcdir}/build" test
fi
}
package() {
if ((DISABLE_MESON)); then
cd $_pkgname
make DESTDIR="${pkgdir}" install
else
DESTDIR="${pkgdir}" ninja -C "${srcdir}/build" install
fi
install -Dm 644 "${srcdir}/linux.gpl" "${pkgdir}/usr/share/gimp/2.99/palettes/Linux.gpl"
}
|