blob: 8e3997970e5ef3ecc16cea2313fe3afc0bbfba1a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
pkgname=1password
_appimagver=0.9.7
_appimage="${pkgname}-${_appimagver}.AppImage"
pkgver=${_appimagver//-/_}
pkgrel=1
pkgdesc="Password manager and secure wallet"
arch=('x86_64')
url='https://1password.com/'
license=('LicenseRef-1Password-Proprietary')
depends=('fuse2' 'zlib' 'hicolor-icon-theme')
options=(!strip)
source=(https://downloads.1password.com/linux/appimage/${_appimage}{,.sig})
noextract=("${_appimage}")
sha256sums=('25a60524bdb83e0c21e42aec2a324f2fcbb47f1d71d1b7854caf8418d4f58aa0'
'aac930742a4fdc04543d61bdf18b3ab55e3fcbc2eb2158cd5e67371061f279ce'
)
validpgpkeys=('3FEF9748469ADBE15DA7CA80AC2D62742012EA22')
prepare() {
# Enable execution of AppImage
chmod +x "${_appimage}"
# Extract AppImage into squashfs-root folder
./"${_appimage}" --appimage-extract
# Set permissions for squashfs-root folder
chmod -R 0755 squashfs-root
}
package() {
# Go to source directory
cd "$srcdir"
# Create directories for installation
install -dm0755 "${pkgdir}"/usr/bin
install -dm0755 "${pkgdir}"/opt
install -dm0755 "${pkgdir}"/usr/share/icons
# Install icons
cp -r squashfs-root/usr/share/icons/hicolor "${pkgdir}"/usr/share/icons/
# Modify .desktop file to run executable instead of AppImage
sed -i -E "s|Exec=AppRun|Exec=/usr/bin/${pkgname}|" squashfs-root/${pkgname}.desktop
# Install desktop file
install -Dm644 squashfs-root/${pkgname}.desktop -t "${pkgdir}"/usr/share/applications/
# Move package contents to opt
mv squashfs-root "${pkgdir}"/opt/${pkgname}
# Symlink /usr/bin executable to opt
ln -s /opt/${pkgname}/${pkgname} "${pkgdir}"/usr/bin/${pkgname}
}
|