blob: 3917dc23546412912e5f6fd262c9cdc95062c085 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Butui Hu <hot123tea123@gmail.com>
pkgname=3dslicer-bin
_pkgname=3dslicer
pkgver=4.11.20210226
pkgrel=1
pkgdesc="A multi-platform, free open source software package for visualization and medical image computing"
arch=('x86_64')
url="https://www.slicer.org"
license=('BSD')
depends=('dbus' 'glib2')
makedepends=('gendesk')
provides=('3dslicer')
conflicts=('3dslicer')
options=(!strip !emptydirs)
source=(
"${_pkgname}-${pkgver}.tar.gz::http://download.slicer.org/download?os=linux&stability=release"
"${_pkgname}.svg::https://github.com/Slicer/Slicer/raw/v4.11/Resources/3DSlicerLogo-app-icon.svg"
)
sha512sums=('882c61da94f378326697ba777cc321d463e768cf00f5e3c85913027a909884a26589abf057a0020a6e02982eb15a1b8065a8e19ff1bba7b0fed89287698a3aa6'
'c23104efcbec3d49b5c26ad5514ed74316423db4aa9e6c7894f02f7ddbe509b577de358dfdd2f7c492963f312b7c146f03d5e41a89ab1298811894dc18746225')
prepare() {
# manually extract tarball due to their unpredicted name
mkdir "${srcdir}/${_pkgname}"
tar xvf "${srcdir}/${_pkgname}-${pkgver}.tar.gz" -C "${srcdir}/${_pkgname}" --strip-components 1
echo "Creating desktop file"
gendesk -f -n --pkgname ${_pkgname} \
--pkgdesc "${pkgdesc}" \
--categories "Graphics;MedicalSoftware;Science;" \
--icon "${_pkgname}" \
--exec "Slicer"
}
package() {
install -d "${pkgdir}/opt" "${pkgdir}/usr/bin"
mv "${srcdir}/${_pkgname}" "${pkgdir}/opt/${_pkgname}"
ln -s /opt/${_pkgname}/Slicer "${pkgdir}/usr/bin"
install -Dm644 "${srcdir}/${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
install -Dm644 "${srcdir}/${_pkgname}.svg" "${pkgdir}/usr/share/pixmaps/${_pkgname}.svg"
}
# vim:set ts=2 sw=2 et:
|