blob: 63c074e9584945d8c66298ba7e1911e7727aa82c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: willemw <willemw12@gmail.com>
pkgname=3ncode-git
pkgver=r38.6de23d1
pkgrel=1
pkgdesc='Graphical video and audio converter for ffmpeg'
arch=(any)
url=https://github.com/NeptuneOS/3ncode
license=(BSD)
depends=(ffmpeg python-pyqt5) # python-pyside2: Alternative Python binding for Qt5
optdepends=(
'faac: codec'
'faad2: codec'
'lame: codec'
'mkvtoolnix-cli: for mkv files'
'opencore-amr: codec'
'opus: codec'
'x264: codec'
'xvidcore: codec')
makedepends=(git)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("$pkgname::git+$url.git")
sha256sums=('SKIP')
pkgver() {
cd $pkgname
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd $pkgname
sed -i 's/=[Ee]ncode$/=3ncode/g' debian/encode.desktop
sed -i 's|/usr/share/encode|/usr/share/3ncode|g' encode
}
package() {
cd $pkgname
install -Dm644 debian/encode.desktop "$pkgdir/usr/share/applications/${pkgname%-git}.desktop"
install -Dm644 qml/img/encode.png "$pkgdir/usr/share/pixmaps/${pkgname%-git}.png"
install -Dm755 encode "$pkgdir/usr/bin/${pkgname%-git}"
install -dm755 "$pkgdir/usr/share/${pkgname%-git}/qml/img"
cp -a ./*.py ./*.qml "$pkgdir/usr/share/${pkgname%-git}"
cp -a qml/*.qml "$pkgdir/usr/share/${pkgname%-git}/qml"
cp -a qml/img/*.png "$pkgdir/usr/share/${pkgname%-git}/qml/img"
}
|