blob: d26d1445bc13943827db5ecbaa901c9ebfc96089 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Nebulosa <nebulosa2007-at-yandex-dot-ru>
pkgname=3x-ui
pkgver=2.8.11
pkgrel=1
pkgdesc="Xray panel supporting multi-protocol multi-user expire day & traffic & IP limit"
arch=(aarch64 armv7h i686 x86_64)
url="https://github.com/MHSanaei/$pkgname"
license=(GPL-3.0-only)
depends=(
glibc
sh
x-ui-xray-core
)
makedepends=(go)
optdepends=(
'acme.sh: Certificate Management'
'fail2ban: IP Limit Management'
'openldap: LDAP integration'
'openssh: SSH Port Forwarding Management'
'speedtest-cli: Speedtest by Ookla'
'ufw: Firewall Management'
)
options=(!debug)
source=(
$url/archive/v$pkgver/$pkgname-$pkgver.tar.gz
${pkgname:1}-updategeo.{service,timer}
)
b2sums=('0de5441f73a743f7ed4efd39891f8342f7fab72e32c9408bfa51a9e76807e52c31e93ee30ebbe5da41674a84fed6f7dc57e924c9bab216331f00618083a6d462'
'a6f4eba028beba4f94d78ce40080e531939f98c9fa265c7a27d6ea17777cb549cd65be0193e390850fc418457e204f478c36f87b66844cb0abc69c893192e970'
'da9c55306c37438f79adfb550d1d0003f14c4d597b170e4424428fc07040391fd904d63f738c46ac92ba13d8c8577b3e4a74bfe119d0f7b914d3e7839c4a0336')
prepare() {
cd $pkgname-$pkgver
sed -i 's|:=/usr/local|:=/usr/lib|;s|:=/etc|:=/usr/lib|' ${pkgname:1}.sh
sed -i 's|&& legacy_version\( 0\)\?|\&\& echo "Please use AUR helper for this function"|g' ${pkgname:1}.sh
sed -i 's|&& uninstall\( 0\)\?|\&\& echo "Please use AUR helper for this function"|g' ${pkgname:1}.sh
sed -i 's|&& update_menu|\&\& echo "Please use AUR helper for this function"|' ${pkgname:1}.sh
sed -i 's|&& update 0$|\&\& echo "Please use AUR helper for this function"|' ${pkgname:1}.sh
sed -i 's|&& update$|\&\& echo "Please use AUR helper for this function"|' ${pkgname:1}.sh
}
build() {
cd $pkgname-$pkgver
export GOCACHE="$srcdir"/go-build
export GOPATH="$srcdir"/go
export CGO_CPPFLAGS=$CPPFLAGS
export CGO_CFLAGS="$CFLAGS -D_LARGEFILE64_SOURCE"
export CGO_CXXFLAGS=$CXXFLAGS
export CGO_LDFLAGS=$LDFLAGS
export CGO_ENABLED=1
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -o build/$pkgname main.go
}
package() {
cd $pkgname-$pkgver
install -vDm 755 ${pkgname:1}.sh "$pkgdir"/usr/bin/${pkgname:1}
install -vDm 755 build/$pkgname "$pkgdir"/usr/lib/${pkgname:1}/${pkgname:1}
install -vDm 644 ${pkgname:1}.service.arch "$pkgdir"/usr/lib/systemd/system/${pkgname:1}.service
install -vDm 644 ../${pkgname:1}-updategeo.{service,timer} -t "$pkgdir"/usr/lib/systemd/system/
}
|