blob: ecdecac872b1f98d110e200f80772fb0b1ea3a90 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: oscareczek <oscareczek at gmail dot com>
pkgname=86box
_pkgname=86Box
pkgver=3.4
pkgrel=1
pkgdesc='An emulator for classic IBM PC clones'
arch=('pentium4' 'x86_64' 'arm7h' 'aarch64')
url='https://86box.net/'
license=('GPL2')
depends=('alsa-lib' 'faudio' 'freetype2' 'libpng' 'libslirp' 'openal' 'qt6-base' 'rtmidi' 'sdl2')
makedepends=('cmake>=3.21' 'ninja' 'qt6-tools')
optdepends=(
'86box-roms: ROM files'
'discord-game-sdk: Discord Rich Presence'
'libpcap: Networking not limited to TCP/IP'
)
options=('!buildflags')
source=(
"https://github.com/${_pkgname}/${_pkgname}/archive/refs/tags/v${pkgver}.tar.gz"
)
sha512sums=('a60034e027bd188343c8eaefe6c56699bf5f7b8016cb1443b081655377bddbd84159cd63362d268a73fc6a5f92ec38544d2fb82aacdb40e8d0eec83bba00cff0')
build() {
case "$CARCH" in
pentium4) _PRESET=regular; _TOOLCHAIN=cmake/flags-gcc-i686.cmake ;;
x86_64) _PRESET=regular; _TOOLCHAIN=cmake/flags-gcc-x86_64.cmake ;;
arm7h) _PRESET=regularndr; _TOOLCHAIN=cmake/flags-gcc-armv7.cmake ;;
aarch64) _PRESET=regularndr; _TOOLCHAIN=cmake/flags-gcc-aarch64.cmake ;;
esac
cmake -S"$_pkgname-$pkgver" -Bbuild --preset "$_PRESET" --toolchain "$_TOOLCHAIN" -DCMAKE_INSTALL_PREFIX=/usr -DUSE_QT6=on -DSLIRP_EXTERNAL=on
cmake --build build
}
package() {
DESTDIR="${pkgdir}" cmake --build "${srcdir}/build" --target install
for i in 48x48 64x64 72x72 96x96 128x128 192x192 256x256 512x512; do
install -Dm644 "$srcdir/$_pkgname-$pkgver/src/unix/assets/$i/net.86box.86Box.png" -t "$pkgdir/usr/share/icons/hicolor/$i/apps"
done
mkdir "$pkgdir/usr/share/applications"
sed 's/^Exec.*/Exec=86Box -P .local\/share\/86Box/' "$srcdir/$_pkgname-$pkgver/src/unix/assets/net.86box.86Box.desktop" > "$pkgdir/usr/share/applications/net.86box.86Box.desktop"
}
|