PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=a52dec-git
pkgver=0.8.0.r0.gc388f3b
pkgrel=1
pkgdesc="A free ATSC A/52 stream decoder"
arch=('i686' 'x86_64')
url="https://git.adelielinux.org/community/a52dec/"
license=('GPL-2.0-or-later')
depends=('glibc')
makedepends=('git')
provides=("a52dec=$pkgver")
conflicts=('a52dec')
options=('staticlibs')
source=("git+https://git.adelielinux.org/community/a52dec.git")
sha256sums=('SKIP')


pkgver() {
  cd "a52dec"

  _tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}

build() {
  cd "a52dec"

  ./bootstrap
  CFLAGS="$CFLAGS -ffat-lto-objects" \
  ./configure \
    --prefix="/usr" \
    --enable-shared
  make
}

check() {
  cd "a52dec"

  #make check
}

package() {
  cd "a52dec"

  make DESTDIR="$pkgdir" install
  install -Dm644 "liba52/a52_internal.h" -t "$pkgdir/usr/include/a52dec"
}