blob: 2b7b67b03e0b43b22f8b2791ad7167936fe64466 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: PolpOnline <aur at t0mmy dot anonaddy dot com>
# Contributor: Eric Biggers <ebiggers3 at gmail dot com>
pkgname=abyss
pkgver=2.3.2
pkgrel=1
pkgdesc="Assembly By Short Sequences - a de novo, parallel, paired-end sequence assembler"
arch=("i686" "x86_64")
url="https://github.com/bcgsc/abyss"
license=("GPL3")
depends=("make" "openmpi" "sqlite")
makedepends=("boost" "sparsehash")
optdepends=(
'pigz: for parallel gzip'
'samtools: to read BAM files'
'zsh: to report time and memory usage'
)
source=("$pkgname-$pkgver.tar.gz::https://github.com/bcgsc/abyss/archive/$pkgver.tar.gz")
sha512sums=('6240872cc79e40fcb83ad4aac2ad08c8e763b9b13a12430e3883e269553ebf96239732cd5bea6dd43fbd9c0f5756ec5d0d393d932dac49f359ebb6fa20594457')
build() {
cd "${pkgname}-${pkgver}"
./autogen.sh
LDFLAGS="${LDFLAGS:-} -L/usr/lib/openmpi" \
./configure --prefix=/usr --disable-werror
make
}
check() {
cd "${pkgname}-${pkgver}"
make check
}
package() {
cd "${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|