blob: dc42ff24ba084805345c4c8423b3296e23f27d72 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Tony Finn <aurcomments at tonyfinn dot com>
# Contributor: lf <packages at lfcode dot ca>
pkgname=acme-dns
pkgver=0.8
pkgrel=3
pkgdesc="DNS server for ACME dns-01 challenges"
arch=('x86_64')
url="https://github.com/joohoi/acme-dns"
license=('MIT')
makedepends=('go')
options=('!strip' '!emptydirs')
source=(
'sysusers.conf'
'tmpfiles.conf'
'acme-dns.service'
"acme-dns-src-v${pkgver}.tar.gz::https://github.com/joohoi/acme-dns/archive/v${pkgver}.tar.gz"
)
sha256sums=('edd9873e5d24736b9164467f7543dab42dc177d6c98b4ca6a572dfcbdd2202a4'
'e8a8b3ffda44a3c346925ba4de197f1b6f139bfe52b9f77e6cb3f87677d3ad98'
'dea89dea17e9f0eff9adf5af56a876ceb738d94f0281a6ece9ca841ec39cf6be'
'9b3b1aeeb7aab58c13ca80f1540d78f963d5ddd1aa7c6c6166d5ef1f7042b742')
backup=('etc/acme-dns/config.cfg')
build() {
cd "$pkgname-$pkgver"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
go build -v
}
package() {
install -Dm644 "acme-dns.service" "$pkgdir/usr/lib/systemd/system/acme-dns.service"
install -Dm644 "sysusers.conf" "$pkgdir/usr/lib/sysusers.d/acme-dns.conf"
install -Dm644 "tmpfiles.conf" "$pkgdir/usr/lib/tmpfiles.d/acme-dns.conf"
cd "$pkgname-$pkgver"
install -Dm755 "$pkgname" "$pkgdir/usr/bin/$pkgname"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm644 config.cfg "$pkgdir/etc/acme-dns/config.cfg"
}
# vim:set ts=2 sw=2 et:
|