summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: decc163045d8bd9654ecfa60dae7ef20d953e724 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
# Maintainer: Tim Lagnese <tim at inept tech>

pkgname=ada-libfswatch-git
pkgver=r16.94c0a5f
pkgrel=3

pkgdesc='High level string and text processing library'
url='https://github.com/AdaCore/ada_libfswatch'
arch=('x86_64')
license=('GPL3')

depends=('gcc-libs' 'fswatch')
makedepends=('git' 'gprbuild' 'gnatcoll-core')

provides=('ada-libfswatch')

source=(
	'git+https://github.com/AdaCore/ada_libfswatch.git'
	'0001-Use-system-libfswatch-install.patch'
	'0002-Build-dynamic-library.patch'
	'0003-Makefile-allow-passing-custom-flags-to-gprbuild.patch'
)
sha1sums=('SKIP'
          '511ac217679b16c6dc8d1276556fd532fa10b0cf'
          'b08e1c9d415982b1e5388d1fa2b17fe4a1558be8'
          '066d1578f3b6f4c8eece49d2650a79b5a0c084c8')

pkgver() {
    cd "$srcdir/ada_libfswatch"
    printf "r%s.%s" \
        "$(git rev-list --count HEAD)" \
        "$(git rev-parse --short HEAD)"
}

prepare() {
	cd "$srcdir/ada_libfswatch"
	patch -p1 < "$srcdir/0001-Use-system-libfswatch-install.patch"
	patch -p1 < "$srcdir/0002-Build-dynamic-library.patch"
	patch -p1 < "$srcdir/0003-Makefile-allow-passing-custom-flags-to-gprbuild.patch"
}

build() {
    cd "$srcdir/ada_libfswatch"

    ADA_FLAGS="$CFLAGS"
    ADA_FLAGS="${ADA_FLAGS//-Wformat}"
    ADA_FLAGS="${ADA_FLAGS//-Werror=format-security}"

    make GPRBUILD_FLAGS="-vh -R -cargs $ADA_FLAGS -largs $LDFLAGS -gargs"
}

package() {
    cd "$srcdir/ada_libfswatch"

	make install DESTDIR="$pkgdir/usr"

    # gprinstall installs a soft link for /usr/lib/libfswatch.so which is already owned by fswatch
    # Remove it
    rm "$pkgdir/usr/lib/libfswatch.so"
}