blob: f980c0ab40f9f7f491909181ad2d5850268a928d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer : Yamada Hayao <hayao@fascode.net>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Phillip Schichtel <phillip.public@schich.tel>
pkgname=adapta-gtk-theme-git
pkgver=3.95.0.11.r2.51c02f689
pkgrel=2
pkgdesc='An adaptive Gtk+ theme based on Material Design Guidelines'
arch=('any')
url='https://github.com/adapta-project/adapta-gtk-theme'
license=('GPL2')
depends=('gtk-engine-murrine' 'gtk3')
makedepends=('git' 'gnome-shell' 'inkscape' 'libxml2' 'parallel' 'sassc')
optdepends=('gnome-shell: The GNOME Shell'
'gnome-flashback: The GNOME flashback shell'
'budgie-desktop: The Budgie desktop'
'cinnamon: The Cinnamon desktop'
'xfdesktop: The Xfce desktop')
provides=('adapta-gtk-theme')
conflicts=('adapta-gtk-theme')
source=('git+https://github.com/adapta-project/adapta-gtk-theme.git')
sha256sums=('SKIP')
pkgver() {
cd adapta-gtk-theme
git describe --tags | sed 's/-/.r/; s/-g/./'
}
build() {
cd adapta-gtk-theme
#bundle install --path .
#export PATH="$(find $PWD/ruby -maxdepth 2 -type d -name bin):$PATH"
./autogen.sh \
--prefix='/usr' \
--enable-parallel \
--enable-chrome \
--enable-plank \
--enable-telegram \
--disable-unity
make
}
package() {
cd adapta-gtk-theme
make DESTDIR="${pkgdir}" install
install -dm 755 "${pkgdir}"/usr/share/plank/themes
ln -s /usr/share/themes/Adapta/plank "${pkgdir}"/usr/share/plank/themes/Adapta
}
# vim: ts=2 sw=2 et:
|