PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: Michael Schubert <mschu.dev at gmail>
pkgname=adaptagrams-git
pkgver=r1181.0503f75
pkgrel=1
pkgdesc="A library of tools and reusable code for adaptive diagramming applications"
arch=('i686' 'x86_64')
url="http://adaptagrams.sourceforge.net/"
license=('LGPL')
optdepends=('cairo')
makedepends=('git')
options=('!libtool')
source=($pkgname::git+https://github.com/mjwybrow/adaptagrams.git)
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/$pkgname"
  ( set -o pipefail
    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

build() {
  cd "$srcdir/$pkgname/cola"
  mkdir m4 || true
  aclocal
  autoreconf --install
  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/$pkgname/cola"
  make DESTDIR="$pkgdir" install
  install -m644 "libcola/exceptions.h" "$pkgdir/usr/include/libcola/"
}