PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Maintainer: Jean Pierre Cimalando <jp-dev@inbox.ru>
pkgname=adlplug-git
_pkgname=ADLplug
pkgver=v1.0.0.alpha.3.r34.2e42c73
pkgrel=1
pkgdesc="FM synthesizer plugin for ADLMIDI with OPL3 chip emulation"
arch=('i686' 'x86_64')
url="https://github.com/jpcima/ADLplug"
license=('GPL')
groups=()
depends=('jack' 'alsa-lib' 'freetype2' 'libxext')
makedepends=('git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
replaces=()
backup=()
options=()
install=
source=('git+https://github.com/jpcima/ADLplug.git'
        'git+https://github.com/Wohlstand/libADLMIDI.git'
        'git+https://github.com/Wohlstand/libOPNMIDI.git'
        'git+https://github.com/jpcima/JUCE.git'
        'git+https://github.com/fmtlib/fmt.git')
noextract=()
md5sums=('SKIP'
         'SKIP'
         'SKIP'
         'SKIP'
         'SKIP')

pkgver() {
  cd "$srcdir/$_pkgname"
  printf "%s" "$(git describe --long | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
}

prepare() {
  cd "$srcdir/$_pkgname"
  git submodule init
  for submodule in \
    thirdparty/libADLMIDI thirdparty/libOPNMIDI \
    thirdparty/JUCE thirdparty/fmt
  do
    git config "submodule.$submodule.url" "$srcdir/`basename "$submodule"`"
  done
  git submodule update
}

build() {
  cd "$srcdir/$_pkgname"
  mkdir build
  cd build
  cmake -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr -DADLplug_CHIP=OPL3 ..
  make
}

package() {
  cd "$srcdir/$_pkgname/build"
  make DESTDIR="$pkgdir/" install
}