blob: 91380d6c13dc06f4da0630627c685edf4f8f541a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Posi <posi1981@gmail.com>
# Contributor: Maxim Baz <$pkgname at maximbaz dot com>
# Contributor: adambot <adambot@gmail.com>
# Contributor: boscowitch <boscowitch@boscowitch.de>
_pkgname=coreutils
_commit=35988dc8d773fcf433ac2d4aa90acd9a713685e3
pkgname=advcpmv
pkgver=9.2
pkgrel=1
pkgdesc="'cp' and 'mv' utilities with progress bar patches"
arch=('x86_64')
license=('GPL3')
url='https://github.com/jarun/advcpmv'
depends=('glibc' 'acl' 'attr')
provides=('acp' 'amv' 'advcp' 'advmv' 'cpg' 'mvg')
source=("https://ftp.gnu.org/gnu/${_pkgname}/${_pkgname}-${pkgver}.tar.xz"{,.sig}
"${pkgname}-${pkgver}-${pkgrel}.patch::https://raw.githubusercontent.com/jarun/advcpmv/${_commit}/advcpmv-0.9-${pkgver}.patch")
validpgpkeys=('6C37DC12121A5006BC1DB804DF6FD971306037D9') # Pádraig Brady
sha256sums=('61a1f410d78ba7e7f37a5a4f50e6d1320aca33375484a3255eddf17a38580423'
'SKIP'
'5dcf0ce663c025b7f2f79d514b2a83c2063bf9f783421efb5fc16fb0ea3f7298')
prepare() {
cd "${_pkgname}-${pkgver}"
patch -Np1 -i "${srcdir}/${pkgname}-${pkgver}-${pkgrel}.patch"
}
build() {
cd "${_pkgname}-${pkgver}"
./configure --prefix=/usr \
--libexecdir=/usr/lib
make
}
package() {
cd "${_pkgname}-${pkgver}"
install -D src/cp "${pkgdir}/usr/bin/advcp"
ln -s advcp "${pkgdir}/usr/bin/acp"
ln -s advcp "${pkgdir}/usr/bin/cpg"
install -D src/mv "${pkgdir}/usr/bin/advmv"
ln -s advmv "${pkgdir}/usr/bin/amv"
ln -s advmv "${pkgdir}/usr/bin/mvg"
}
|