blob: 6e7da9d92bd903657415a13a3ca8d8fffefaa500 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: éclairevoyant
# Contributor: Philip Goto <philip dot goto at gmail.com>
_pkgname=adwaita-icon-theme
pkgbase="$_pkgname-git"
pkgname=("$pkgbase" 'adwaita-cursors-git')
pkgver=43.r68.g855de98ff
pkgrel=1
pkgdesc='GNOME standard icons'
arch=('any')
url="https://gitlab.gnome.org/GNOME/$_pkgname"
license=('LGPL3' 'CCPL:by-sa')
depends=('hicolor-icon-theme' 'gtk-update-icon-cache' 'librsvg')
makedepends=('git' 'gtk3')
source=("git+$url.git")
b2sums=('SKIP')
pkgver() {
cd $_pkgname
git describe --long --tags | sed 's/[^-]*-g/r&/;s/-/./g'
}
prepare() {
cd $_pkgname
autoreconf -fvi
}
build() {
cd $_pkgname
./configure --prefix=/usr
make
}
check() {
make -C $_pkgname check
}
package_adwaita-icon-theme-git() {
depends+=('adwaita-cursors')
provides=("$_pkgname")
conflicts=("$_pkgname")
make -C $_pkgname DESTDIR="$pkgdir" install
rm -rf "$pkgdir/usr/share/icons/Adwaita/cursors/"
}
package_adwaita-cursors-git() {
pkgdesc='GNOME standard cursors'
unset depends
provides=('adwaita-cursors')
conflicts=('adwaita-cursors')
install -dm755 "$pkgdir/usr/share/icons/Adwaita/"
cp -r --no-preserve=ownership $_pkgname/Adwaita/cursors "$pkgdir/usr/share/icons/Adwaita/"
}
|