PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Mark Wagie <mark dot wagie at tutanota dot com>
# Contributor: Victor Homic <aur (at) dothomic (dot) de>
# Contributor: Iyán Méndez Veiga <me (at) iyanmv (dot) com>
# Contributor: Aniket Pradhan <aniket17133 (at) iiitd (dot) ac (dot) in>
# Contributor: Martin Briza <m (at) rtinbriza (dot) cz>

_base=adwaita-qt
pkgbase=adwaita-solarized-qt
pkgname=(adwaita-solarized-qt5 adwaita-solarized-qt6)
pkgver=1.4.2
pkgrel=1
pkgdesc='A solarized style to bend Qt applications to look like they belong into GNOME Shell'
arch=(x86_64)
url='https://github.com/FedoraQt/adwaita-qt'
license=(GPL)
makedepends=(cmake qt5-x11extras qt6-base)
source=(
    https://github.com/FedoraQt/adwaita-qt/archive/$pkgver/$_base-$pkgver.tar.gz
    solarized.patch
)
sha256sums=('cd5fd71c46271d70c08ad44562e57c34e787d6a8650071db115910999a335ba8'
            'c6263c891ef7f53eeffcacbfa9547c98779d5cbf558375961ae763638f10ac24')

prepare() {
    cd "$_base-$pkgver"

    patch -p1 < "$srcdir/solarized.patch"
}

build() {
  cmake -B build-qt5 -S $_base-$pkgver \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DUSE_QT6=OFF
  cmake --build build-qt5

  cmake -B build-qt6 -S $_base-$pkgver \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DUSE_QT6=ON
  cmake --build build-qt6
}

package_adwaita-solarized-qt5() {
  pkgdesc='A solarized style to bend Qt5 applications to look like they belong into GNOME Shell'
  depends=(qt5-x11extras)
  replaces=(adwaita-qt)
  conflicts=(adwaita-qt5)

  DESTDIR="$pkgdir" cmake --install build-qt5
}

package_adwaita-solarized-qt6() {
  pkgdesc='A solarized style to bend Qt6 applications to look like they belong into GNOME Shell'
  depends=(qt6-base)
  conflicts=(adwaita-qt6)

  DESTDIR="$pkgdir" cmake --install build-qt6
}