PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

_pkgname=adwifi
pkgname=$_pkgname-git
pkgver=0.1.0.r44.g483f9fa
pkgrel=1
pkgdesc="A libadwaita Wi-Fi manager backed by iwd"
arch=('any')
url="https://github.com/rzesm/adwifi"
license=('GPL-3.0-or-later')

depends=(
    'python-dbus-next'
    'python-gobject'
    'gtk4'
    'libadwaita'
    'python-cairo'
    'iwd'
    'ookla-speedtest-bin'
)

makedepends=(
    'git'
    'python-build'
    'python-installer'
    'python-poetry-core'
)

provides=("$_pkgname")
conflicts=("$_pkgname")
source=("$_pkgname::git+$url.git")
sha256sums=('SKIP')

pkgver() {
    cd "$_pkgname"
    printf "0.1.0.r%s.g%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd "$_pkgname"
    python -m build --wheel --no-isolation
}

package() {
    cd "$_pkgname"
    python -m installer --destdir="$pkgdir" dist/*.whl
    install -Dm644 assets/adwifi.desktop -t "$pkgdir/usr/share/applications/"
    install -Dm644 assets/adwifi.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/adwifi.svg"
}