PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: Konstantin Shalygin <k0ste@k0ste.ru>
# Contributor: Konstantin Shalygin <k0ste@k0ste.ru>

pkgname='aeon'
pkgver='0.12.8.0'
pkgrel='2'
pkgdesc='A lightweight CryptoNote digital currency.'
url="https://github.com/${pkgname}ix/${pkgname}"
depends=('boost-libs' 'openssl' 'zeromq' 'pcsclite' 'icu' 'readline')
makedepends=('git' 'cmake' 'boost' 'doxygen' 'rapidjson')
license=('custom:Cryptonote')
arch=('x86_64' 'i686' 'armv7h' 'aarch64')
source=("${pkgname}d.service"
	"${pkgname}.sysusers"
	"${pkgname}.tmpfiles"
	"${pkgname}d.conf"
	"${url}/archive/v${pkgver}-${pkgname}.tar.gz"
	"https://raw.githubusercontent.com/arcmags/repo/master/pkgbuild/aeon/boost.patch")
sha256sums=('5212dff199bb3880191292976cd8278dcdbae64f9c0ab39a9c2a91a4733186c3'
            'a0cdf75b86073829f4033e367f36e9418dc20556e7adfa6ffac8653c67cd6337'
            '1da20b66d52db4f1c5b3106cf27ee54033650a0e36c5c775b25c9e86e6027be0'
            '3ef15e3c9e2d146c415f2e483dd10e4ec36f653e4684c254d9f69a5fb699036b'
            '4c591edba109d900416f0a069b6c56ff1772099849928ff9db5664e5a17a28bf'
            '824000b8c1a9babc87ab36d32ec0bc38fa58caee813f0f575e81f9bcccfc10af')
backup=("etc/${pkgname}d.conf")

prepare() {
  cd "${pkgname}-${pkgver}-${pkgname}"
  git clone git://github.com/monero-project/miniupnp.git external/miniupnp
  git clone git://github.com/monero-project/unbound.git external/unbound
  git -C external/miniupnp checkout monero
  git -C external/unbound checkout monero
  patch -p1 -i "${srcdir}/boost.patch"
}

build() {
  cd "${pkgname}-${pkgver}-${pkgname}"
  make release
}

package() {
  cd "${pkgname}-${pkgver}-${pkgname}"
  install -Dm0644 "${srcdir}/${pkgname}.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/${pkgname}.conf"
  install -Dm0644 "${srcdir}/${pkgname}.sysusers" "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
  install -Dm0644 "${srcdir}/${pkgname}d.service" "${pkgdir}/usr/lib/systemd/system/${pkgname}d.service"
  install -Dm0644 "${srcdir}/${pkgname}d.conf" "${pkgdir}/etc/${pkgname}d.conf"
  cp -r "build/release/bin" "${pkgdir}/usr"
}