blob: e76e7c6eb5309d19921c1b6ab39a5643785da082 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: William Turner <willtur.will@gmail.com>
pkgname=afdko
pkgver=3.9.5
pkgrel=2
pkgdesc='Adobe Font Development Kit for OpenType'
arch=(x86_64)
url="https://github.com/adobe-type-tools/$pkgname"
license=(custom)
_py_deps=(booleanoperations
brotli # for fonttools[woff]
defcon
fontmath
fontparts
fontpens # for defcon[pens]
fonttools
fs # for fonttools[ufo]
lxml # for fonttools[lxml] and defcon[lxml]
tqdm
ufonormalizer
ufoprocessor
unicodedata2 # for fonttools[unicode]
zopfli) # for fonttools[woff]
depends=(python
"${_py_deps[@]/#/python-}"
psautohint)
makedepends=(cmake
git # Upstream Issue: https://github.com/adobe-type-tools/afdko/issues/1407
python-setuptools-scm
python-scikit-build)
checkdepends=(python-pytest)
conflicts=(spot-client)
_archive="$pkgname-$pkgver"
source=("$url/releases/download/$pkgver/$_archive.tar.gz")
sha256sums=('cbe6bd9a9a147c2754c0ace8fd243386478f44164c3fbc530d6dbd77bacc8109')
prepare () {
cd "$_archive"
sed -i -e 's/==/>=/g;s/,<=[0-9.]\+//' requirements.txt
sed -i -E "/'(wheel|cmake|ninja)',?$/d" setup.py
}
build() {
cd "$_archive"
python setup.py build_ext
python setup.py build
}
check() {
cd "$_archive"
# Upstream test suite uses vendored deps and the paths are foobared
# PYTHONPATH=python pytest
}
package() {
cd "$_archive"
python setup.py install --root="$pkgdir" --optimize=1 --skip-build
install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE.md
}
|