blob: ba0be45b2b3d1dea36d66683f0072f91d1f87e91 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Giancarlo Razzolini <grazzolini@archlinux.org>
# Maintainer: Daniel M. Capella <polyzen@archlinux.org>
# Contributor: Kazuo Teramoto <kaz.rag at gmail.com>
pkgname=afew-git
_pkgname=${pkgname%-git}
pkgver=3.0.1.r78.gbc09b14
pkgrel=1
epoch=1
pkgdesc='Initial tagging script for notmuch mail'
arch=(any)
url=https://github.com/afewmail/afew
license=(ISC)
depends=(
notmuch
python-chardet
python-cffi
python-dkim
python-setuptools
)
makedepends=(
git
python-build
python-installer
python-setuptools-scm
python-sphinx
python-wheel
)
optdepends=('python-pyinotify: for --watch')
checkdepends=(python-freezegun)
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git+$url.git")
b2sums=(SKIP)
pkgver() {
cd "$_pkgname"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$_pkgname"
python -m build --wheel --skip-dependency-check --no-isolation
PYTHONPATH="build:$PYTHONPATH" sphinx-build -b man docs build
}
check() {
cd "$_pkgname"
python -m unittest discover "$_pkgname"/tests
}
package() {
cd "$_pkgname"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 -t "$pkgdir"/usr/share/man/man1 build/"$_pkgname".1
install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname LICENSE
}
|