blob: 3f816ad777a63558febee48efbfa9e9aa2b86dcc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Contributor: tsester <univ@lavabit.com>
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
pkgname=agedu-git
pkgver=20211128.r150.8cd63c5
pkgrel=1
pkgdesc="Track down wasted disk space"
arch=('i686' 'x86_64')
url="http://www.chiark.greenend.org.uk/~sgtatham/agedu/"
license=('custom:MIT')
makedepends=('git' 'halibut' 'cmake')
depends=('glibc')
provides=('agedu')
conflicts=('agedu')
source=("git+https://git.tartarus.org/simon/agedu.git")
md5sums=('SKIP')
pkgver() {
cd ${pkgname%-git}
printf "%s.r%s.%s" $(git log -1 --format="%cd" --date=short|tr -d - ) $(git rev-list --count HEAD) $(git rev-parse --short HEAD)
}
build() {
cd ${pkgname%-git}
[[ -d build ]] || mkdir build
cd build
cmake -DCMAKE_INSTALL_PREFIX:PATH=/usr ..
make
}
package() {
cd ${pkgname%-git}/build
make DESTDIR="$pkgdir/" install
install -Dm644 ../LICENCE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
|