blob: e4e4a372588d9612d5d09d312b88104b44767705 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: zan <zan@420blaze.it>
pkgname=ajour-git
_name=${pkgname%-git}
pkgver=0.3.4.r33.3dd767f
pkgrel=1
pkgdesc='World of Warcraft addon manager written in Rust'
url='https://www.getajour.com'
license=(MIT)
arch=(x86_64)
depends=(fontconfig freetype2 hicolor-icon-theme libxcb openssl)
makedepends=(cargo rust icoutils git)
conflicts=(ajour)
provides=(ajour)
source=("git+https://github.com/casperstorm/$_name.git"
"$_name.desktop")
sha256sums=('SKIP'
'd356c0f7ab3087a087e2ff261bf6348e62e87190805fa166fcbe9e3f8b64fb0d')
pkgver() {
cd "$_name"
printf "%s" "$(git describe --tags | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
}
build() {
cd "$_name"
cargo build --release
icotool "resources/windows/ajour.ico" -x
}
package() {
install -Dm644 "$_name.desktop" "$pkgdir/usr/share/applications/$_name.desktop"
cd "$_name"
install -Dm755 "target/release/$_name" "$pkgdir/usr/bin/$_name"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
for i in "1 16" "2 24" "3 32" "4 48" "5 256";
do
set -- $i
install -Dm644 "${_name}_$1_$2x$2x32.png" "$pkgdir/usr/share/icons/hicolor/$2x$2/apps/$_name.png"
done
}
|