PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Jerome Leclanche <jerome.leclanche+arch@gmail.com>

_gitname=akonadi
pkgname=$_gitname-git
pkgver=r3157.3ccf157
pkgrel=1
pkgdesc="PIM layer, which provides an asynchronous API to access all kind of PIM data"
arch=('i686' 'x86_64')
url="http://www.kde.org"
license=('LGPL')
depends=('qt5-base' 'shared-mime-info' 'mariadb')
makedepends=('git' 'extra-cmake-modules-git' 'postgresql')
conflicts=("$_gitname")
provides=("$_gitname")
source=("git://anongit.kde.org/$_gitname")
install=$pkgname.install
sha256sums=("SKIP")

pkgver() {
  cd $_gitname
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../$_gitname \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF \
    -DDATABASE_BACKEND=SQLITE \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}