blob: 9ae791c2707ac46483800ebd7f5f6f0fde2bbf4c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# $Id$
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
pkgbase=akonadi-qt4
pkgname=(libakonadi-qt4 akonadi-qt4)
pkgver=1.13.0
pkgrel=14
pkgdesc="PIM layer, which provides an asynchronous API to access all kind of PIM data (Qt4 version)"
arch=('x86_64')
url='http://community.kde.org/KDE_PIM/Akonadi'
license=('LGPL')
makedepends=('cmake' 'automoc4' 'boost' 'postgresql' 'mariadb' 'qt4' 'libxslt')
source=("https://download.kde.org/stable/akonadi/src/akonadi-${pkgver}.tar.bz2"
dont-leak-old-external-payload-files.patch)
sha256sums=('8c7f690002ea22c139f3a64394aef2e816e00ca47fd971af7d54a66087356dd2'
'e6644929ebec09986113be49f9aabf23e47e04585295319787ff7777e8af31b9')
prepare() {
mkdir -p build
cd akonadi-$pkgver
# https://bugs.kde.org/show_bug.cgi?id=341884
patch -p1 -i ../dont-leak-old-external-payload-files.patch
}
build() {
cd build
cmake ../akonadi-$pkgver \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DINSTALL_QSQLITE_IN_QT_PREFIX=TRUE \
-DQT_QMAKE_EXECUTABLE=qmake-qt4 \
-DWITH_SOPRANO=OFF
make
}
package_libakonadi-qt4() {
pkgdesc='Qt4 akonadi libraries'
depends=('qt4')
conflicts=('akonadi<15')
cd build
make DESTDIR="$pkgdir" install
# conflicts with akonadi
rm -r "$pkgdir"/usr/{bin,share}
}
package_akonadi-qt4() {
depends=(libakonadi-qt4 boost-libs mariadb)
conflicts=(akonadi)
replaces=('akonadi<15')
cd build
make DESTDIR="$pkgdir" install
# provided by libakonadi-qt4
rm -r "$pkgdir"/usr/{lib,include}
}
|