PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

# Maintainer: zxp19821005 <zxp19821005 at 163 dot com>
pkgname=akuse
_pkgname=Akuse
pkgver=0.1.2
pkgrel=1
pkgdesc="Simple and easy to use anime streaming desktop app without ads."
arch=('any')
url="https://github.com/akuse-app/Akuse"
license=('GPL3')
conflicts=("${pkgname}")
depends=('bash' 'electron25')
makedepends=('gendesk' 'npm' 'nodejs')
source=("${pkgname}-${pkgver}.zip::${url}/archive/refs/tags/${pkgver}.zip"
    "clientData.js"
    "${pkgname}.sh")
sha256sums=('1f947ce244b9adee9964f3bacba03bc2a8b29b3822dfb9400f27dc9953afed11'
            '2b268bdffb07dac827d76861fe2efe66969bdf418e016c364fb3dd02b6cd2455'
            'b24142f7a1722021cf93134af3eccc3ced1b484500f7ee7d8f22a54b594329aa')
build() {
    gendesk -q -f -n --categories "AudioVideo" --name "${_pkgname}" --exec "${pkgname}"
    cd "${srcdir}/${_pkgname}-${pkgver}"
    sed -e '81,83d' -e '/"deb"/d' -e 's|"AppImage",|"AppImage"|g' -i package.json
    cp "${srcdir}/clientData.js" "${srcdir}/${_pkgname}-${pkgver}/src/modules"
    npm install
    npm run dist:linux
}
package() {
    install -Dm755 "${srcdir}/${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"
    install -Dm644 "${srcdir}/${_pkgname}-${pkgver}/dist/linux-unpacked/resources/app.asar" -t "${pkgdir}/opt/${pkgname}/resources"
    install -Dm644 "${srcdir}/${pkgname}.desktop" -t "${pkgdir}/usr/share/applications"
    install -Dm644 "${srcdir}/${_pkgname}-${pkgver}/assets/img/icon/icon.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
    install -Dm644 "${srcdir}/${_pkgname}-${pkgver}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}