blob: 032f5982245cb114f8604e4e445e7d7f8c760de2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
#!/bin/bash
# Author: Justin Jagieniak <justin@jagieniak.net>
# Contributor: Rye Mutt
# Maintainers: Xenhat Hex (me@xenh.at), Justin Jagieniak <justin@jagieniak.net>
# shellcheck disable=2034,3030,2154
pkgname=alchemy-next-viewer-git
pkgver=6.5.5.48672.53b082b0a2
pkgrel=1
pkgdesc="This is the next generation of Alchemy Viewer! - Git Source build"
arch=('x86_64')
url=https://www.alchemyviewer.org
license=('LGPL')
depends=(dbus-glib glu gtk3 libgl libidn libjpeg-turbo libpng libxss libxml2 mesa nss openal sdl2 vlc zlib)
makedepends=('cmake' 'gcc' 'python-virtualenv' 'python-pip' 'git' 'boost' 'xz' 'ninja')
optdepends=(
'alsa-lib: ALSA support'
'freealut: OpenAL support'
'gamemode: Gamemode support'
'lib32-libidn11: SLVoice support'
'lib32-libsndfile: SLVoice support'
'lib32-util-linux: SLVoice support'
'lib32-gstreamer0.10: SLVoice support'
'libpulse: PulseAudio support'
'mesa-libgl: Intel, Radeon, Nouveau support'
'nvidia-libgl: NVIDIA support'
'nvidia-utils: NVIDIA support')
provides=('alchemy-viewer')
options=(!emptydirs !makeflags !strip !lto)
install=alchemy.install
source=("${pkgname}"::'git+https://git.alchemyviewer.org/alchemy/alchemy-next.git#branch=main')
md5sums=('SKIP')
sha256sums=('SKIP')
b2sums=('SKIP')
pkgver() {
cd "${pkgname}" || exit 1
( set -o pipefail
git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "%s.%s.%s" "$(cat indra/newview/VIEWER_VERSION.txt)" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
prepare() {
cd "${pkgname}" || exit 1
git fetch --prune
git checkout main
git pull --autostash
git checkout "${AL_GIT_REVISION:-origin/main}"
}
build() {
cd "${pkgname}" || exit 1
virtualenv "/tmp/${pkgname}/.venv" -p python3
source "/tmp/${pkgname}/.venv/bin/activate"
pip install --upgrade certifi
if command -v autobuild; then
abver="$(autobuild --version)"
echo "Found ${abver}"
if [ "${abver}" = "autobuild 2.1.0" ]; then
echo "Reinstalling autobuild to work around some bugs"
pip3 uninstall --yes autobuild
fi
fi
pip3 install --upgrade autobuild -i https://git.alchemyviewer.org/api/v4/projects/54/packages/pypi/simple --extra-index-url https://pypi.org/simple
# we have a lot of files, relax ulimit to help performance
ulimit -n 20000
# shellcheck disable=SC2153
autobuild configure -A 64 -c ReleaseOS -- -DLL_TESTS:BOOL=OFF -DDISABLE_FATAL_WARNINGS=ON -DUSE_LTO:BOOL="$(grep -cq '[^!]lto' <<< "${OPTIONS}" && echo 'ON' || echo 'OFF')" -DVIEWER_CHANNEL="Alchemy Test"
cd "build-linux-64"
loadavg=$(nproc)
if [[ ${loadavg} -gt 1 ]]; then
if [[ ${loadavg} -le 8 ]]; then loadavg=$((loadavg - 1))
else
loadavg=$((loadavg - 2))
fi
fi
time ninja -l${loadavg}
}
package() {
mkdir -p "${pkgdir}/opt"
mkdir -p "${pkgdir}/usr/local/share/applications"
# Patch shortcut to avoid duplicated entries
sed -i 's;Name=Alchemy;Name=Alchemy (git build);' "${pkgname}/build-linux-64/newview/packaged/etc/refresh_desktop_app_entry.sh"
sed -i 's;alchemy-viewer\.desktop;'"${pkgname}\.desktop"';' "${pkgname}/build-linux-64/newview/packaged/etc/refresh_desktop_app_entry.sh"
mv "${pkgname}/build-linux-64/newview/packaged" "${pkgdir}/opt/${pkgname}"
}
|