blob: c8624d3c09af370a731b711fdba9c7d606a3c106 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: Hildigerr Vergaray <Maintainer at YmirSystems dot com>
# Contributor: Frederic Bezies <fredbezies at gmail dot com>
# Contributors: Marcin Skory, Arkham, Christoph Zeiler, Jacek Poplawski, carstene1ns
pkgname=alephone
_pkgdate=20250829
pkgver=1.11_$_pkgdate
pkgrel=3
pkgdesc='A free, enhanced port of the classic FPS "Marathon 2" by Bungie Software'
arch=('i686' 'x86_64')
url="https://alephone.lhowon.org/"
license=('GPL3')
depends=('boost-libs' 'sdl2_image' 'sdl2_ttf' 'openal' 'libsndfile' 'glu')
optdepends=(
'curl: for stats upload to lhowon.org'
'miniupnpc: for opening router ports'
'zziplib: for using zipped plugins'
'libvpx: for film export'
'libmatroska: for film export'
'libebml: for film export'
'libvorbis: for film export'
'libyuv: for film export and video playback'
'alephone-eternalx: community-made scenario'
'alephone-evil: community-made scenario'
'alephone-infinity: original data for Marathon Infinity'
'alephone-marathon: M1A1 data converted for AlephOne'
'alephone-marathon2: original data for Marathon 2: Durandal')
makedepends=(
'asio' 'boost' 'mesa'
'curl' 'miniupnpc' 'zziplib'
'libvpx' 'libmatroska' 'libebml' 'libvorbis' 'libyuv'
'icoutils')
source=("https://github.com/Aleph-One-Marathon/alephone/releases/download/release-$_pkgdate/AlephOne-$_pkgdate.tar.bz2")
sha256sums=('e7c447034aa35dd85ca6836dd8367034c4f4512aa0d14e9781d7033946098806')
prepare() {
cd AlephOne-$_pkgdate
# convert the windows icons
cd Resources/Windows
icotool -x -w 48 alephone.ico -o "$srcdir"/alephone.png
icotool -x -w 48 marathon.ico -o "$srcdir"/alephone-marathon.png
icotool -x -w 48 marathon2.ico -o "$srcdir"/alephone-marathon2.png
icotool -x -w 48 marathon-infinity.ico -o "$srcdir"/alephone-infinity.png
}
build() {
cd AlephOne-$_pkgdate
export CXXFLAGS="$CXXFLAGS -fsanitize=undefined" #Issue#518
./configure --prefix=/usr
make
}
package() {
cd AlephOne-$_pkgdate
make DESTDIR="$pkgdir/" install
# icons
install -d "$pkgdir"/usr/share/icons
install -m644 "$srcdir"/*.png "$pkgdir"/usr/share/icons
# docs
#install -Dm644 README.txt "$pkgdir"/usr/share/doc/alephone/README
#install -m644 docs/*.html "$pkgdir"/usr/share/doc/alephone
}
|