blob: f7aab86e2d5a6d470b862f1aca636e53ca09dbfc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
# Maintainer : bartus <arch-user-repoᘓbartus.33mail.com>
_name=alice-vision
pkgname=${_name}
pkgver=2.2.0
pkgrel=1
pkgdesc="Photogrammetric Computer Vision Framework which provides a 3D Reconstruction and Camera Tracking algorithms"
arch=('i686' 'x86_64')
url="https://alicevision.github.io/"
license=('MPL2' 'MIT')
groups=()
conflicts=(alice-vision-git)
provides=(alice-vision)
depends=('openblas-lapack' 'gflags' 'glfw-x11' 'alembic' 'boost-libs' 'openexr' 'openimageio' 'opengv-git' 'flann' 'coin-or-coinutils' 'coin-or-clp' 'coin-or-lemon' 'coin-or-osi' 'google-glog' 'freetype2')
makedepends=('boost' 'eigen' 'ceres-solver' 'git' 'cmake')
source=("https://github.com/alicevision/AliceVision/archive/v${pkgver}.tar.gz"
"geogram::git+https://github.com/alicevision/geogram.git"
"MeshSDFilter::git+https://github.com/alicevision/MeshSDFilter.git#branch=av_develop"
"nanoflann::git+https://github.com/alicevision/nanoflann.git"
"submodule.patch"
)
md5sums=('a9d5cd07ed33c0b73390b11170b3b11f'
'SKIP'
'SKIP'
'SKIP'
'eb62c8be5a0d7ce537a928314c9d0028')
_CMAKE_FLAGS=(
-DCMAKE_INSTALL_PREFIX=/usr
-DCMAKE_INSTALL_LIBDIR=lib
-DEIGEN_INCLUDE_DIR_HINTS=/usr/include/eigen3
-DFLANN_INCLUDE_DIR_HINTS=/usr/include/flann
-DCOINUTILS_INCLUDE_DIR_HINTS=/usr/include/coin
-DLEMON_INCLUDE_DIR_HINTS=/usr/include/lemon
-DCLP_INCLUDE_DIR_HINTS=/usr/include/coin
-DOSI_INCLUDE_DIR_HINTS=/usr/include/coin
-DCERES_DIR=/usr/include/ceres
-DALICEVISION_BUILD_DOC=OFF
)
((DISABLE_CUDA)) && { _CMAKE_FLAGS+=('-DALICEVISION_USE_CUDA=OFF')
DISABLE_UTE=1 # Disable uncertaintyTE as it also depends on cuda
} || { makedepends+=('cuda')
_CMAKE_FLAGS+=('-DCUDA_HOST_COMPILER=/opt/cuda/bin/gcc')
}
((DISABLE_UTE)) || { source+=("ute_lib::git+https://github.com/alicevision/uncertaintyTE.git")
md5sums+=('SKIP')
makedepends+=('magma')
_CMAKE_FLAGS+=( -DMAGMA_ROOT=/opt/magma
-DUNCERTAINTYTE_DIR=${srcdir}/ute_bin )
}
_path="AliceVision-${pkgver}"
prepare() {
cd ${srcdir}/${_path}
patch -Np1 -i ${srcdir}/submodule.patch
rm -rf src/dependencies/{MeshSDFilter,nanoflann}
cp -r ${srcdir}/MeshSDFilter src/dependencies/MeshSDFilter
cp -r ${srcdir}/nanoflann src/dependencies/nanoflann
}
build() {
cd ${srcdir}
((DISABLE_UTE)) || {
msg2 "Build uncertaintyTE library"
mkdir -p ute_build && cd ute_build
cmake -DCMAKE_INSTALL_PREFIX=/ -DMAGMA_ROOT=/opt/magma ../ute_lib
make
make DESTDIR="../ute_bin" install
cd ..
}
msg2 "Build geogram library"
mkdir -p geogram_build && cd geogram_build
cmake -DCMAKE_INSTALL_PREFIX=/ -DGEOGRAM_LIB_ONLY=ON -DGEOGRAM_USE_SYSTEM_GLFW3=ON -DCMAKE_BUILD_TYPE:STRING=Debug -DVORPALINE_PLATFORM:STRING=Linux64-gcc-dynamic ../geogram
make
make DESTDIR="../geogram_bin" install
cd ..
msg2 "Build AliceVision library"
mkdir -p build && cd build
cmake ${_CMAKE_FLAGS[@]} -DGEOGRAM_INSTALL_PREFIX=${srcdir}/geogram_bin ../${_path}
make
}
package() {
((DISABLE_UTE)) || {
msg2 "Install uncertaintyTE"
cd ${srcdir}/ute_build
make DESTDIR=${pkgdir}/usr install
}
msg2 "Install geogram"
cd ${srcdir}/geogram_build
make DESTDIR=${pkgdir}/usr install
cd ${srcdir}/build
make DESTDIR=${pkgdir} install
#fix conflict with openmvg
rm ${pkgdir}/usr/lib/libvlsift.a
}
# vim:set ts=2 sw=2 et:
|