summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 2fac42047251273b5f0e4bece034e037e44967d6 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
# Maintainer: Yardena Cohen <yardenack at gmail dot com>

gitname=alpine
pkgname=$gitname-git
pkgver=2.21.9.223.18b1d64
pkgrel=1
pkgdesc="Fork of the PINE mail client (git)"
arch=('i686' 'x86_64')
url='http://patches.freeiz.com/alpine/'
license=('APACHE')
depends=(
    'gettext'
    'krb5'
    'libldap'
    'pam'
)
makedepends=('git')
provides=('alpine' 'pine' 're-alpine')
conflicts=('alpine' 'pine' 're-alpine')
replaces=('alpine' 'pine' 're-alpine')
source=("git+http://repo.or.cz/${gitname}.git")
sha512sums=('SKIP')

pkgver() {
    cd "${srcdir}/${gitname}"

    # we recently went
    # from 2.21.204.5117359
    # to   2.21.1.209.a9d7a00
    # which rightfully confused pacman's version ordering
    # so let's add a .0 to versions with only one dot
    local v=$(cat VERSION)
    [[ "$v" =~ ^[^\.]+\.[^\.]+\..*$ ]] || v=$v.0

    local ver="${v}.$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
    printf "%s" "${ver//-/.}"
}
build() {
   cd "${srcdir}/${gitname}"
   LIBS+="-lpam -lkrb5 -lcrypto" ./configure --prefix=/usr \
        --without-passfile --without-tcl --disable-shared \
        --with-system-pinerc=/etc/${pkgname}.d/pine.conf \
        --with-system-fixed-pinerc=/etc/${pkgname}.d/pine.conf.fixed
  make
}
package() {
   cd "${srcdir}/${gitname}"
   make DESTDIR="${pkgdir}" install
}